converseen/trunk/PKGBUILD

   1 # Maintainer: Balló György <ballogyor+arch at gmail dot com>
   2 # Contributor: Giovanni Scafora <giovanni@archlinux.org>
   3 # Contributor: archtux <antonio.arias99999 at gmail.com>
   4
   5 pkgname=converseen
   6 pkgver=0.9.11.1
   7 pkgrel=1
   8 pkgdesc='Batch image converter and resizer'
   9 arch=('x86_64')
  10 url='http://converseen.fasterland.net/'
  11 license=('GPL3')
  12 depends=('hicolor-icon-theme' 'imagemagick' 'qt5-base')
  13 makedepends=('cmake' 'qt5-tools')
  14 source=("https://downloads.sourceforge.net/$pkgname/$pkgname-$pkgver.tar.bz2")
  15 sha256sums=('85511aed2644a7e87f5bcbe60cbc3edcbdcfbb2c4bb9416df939ba84ad31a503')
  16
  17 prepare() {
  18   cd $pkgname-$pkgver
  19   convert res/converseen.png +set date:create +set date:modify -resize 256x256 -alpha on res/converseen.png
  20   sed -i 's|/share/pixmaps|/share/icons/hicolor/256x256/apps|' CMakeLists.txt
  21 }
  22
  23 build() {
  24   cmake -B build -S $pkgname-$pkgver \
  25     -DCMAKE_INSTALL_PREFIX=/usr
  26   cmake --build build
  27 }
  28
  29 package() {
  30   DESTDIR="$pkgdir" cmake --install build
  31 }