croc/repos/community-x86_64/PKGBUILD

   1 # Maintainer: Maxim Baz <$pkgname at maximbaz dot com>
   2 # Maintainer: Caleb Maclennan <caleb@alerque.com>
   3 # Contributor: Mikuro Kagamine <mikurok@forgecrushing.com>
   4
   5 pkgname=croc
   6 pkgver=9.6.4
   7 pkgrel=1
   8 pkgdesc='Easily and securely send things from one computer to another.'
   9 arch=('x86_64')
  10 url="https://github.com/schollz/${pkgname}"
  11 license=('MIT')
  12 depends=('glibc')
  13 makedepends=('go')
  14 source=("${url}/releases/download/v${pkgver}/${pkgname}_${pkgver}_src.tar.gz")
  15 sha256sums=('012e8e836c76e3432fecac924e4d44a5bee73cc2fa30f4ecfb1b322bcd83f089')
  16
  17 build() {
  18     cd "${pkgname}-${pkgver}"
  19     export CGO_CPPFLAGS="${CPPFLAGS}"
  20     export CGO_CFLAGS="${CFLAGS}"
  21     export CGO_CXXFLAGS="${CXXFLAGS}"
  22     export CGO_LDFLAGS="${LDFLAGS}"
  23     export GOFLAGS="-buildmode=pie -trimpath -ldflags=-linkmode=external -mod=vendor -modcacherw -buildvcs=false"
  24     go build
  25 }
  26
  27 check() {
  28     cd "${pkgname}-${pkgver}"
  29     go test ./...
  30 }
  31
  32 package() {
  33     cd "${pkgname}-${pkgver}"
  34     install -Dm755 -t "${pkgdir}/usr/bin/" "${pkgname}"
  35     install -Dm644 -t "${pkgdir}/usr/lib/systemd/system/" "${pkgname}.service"
  36     install -Dm644 -t "${pkgdir}/usr/share/licenses/${pkgname}/" LICENSE
  37 }