dcd/trunk/PKGBUILD

   1 # Maintainer: Dan Printzell <wild@archlinux.org>
   2 # Maintainer: Filipe Laíns (FFY00) <lains@archlinux.org>
   3 # Contributor: Jaroslav Lichtblau <svetlemodry@archlinux.org>
   4 # Contributor: Mihails Strasuns <public@dicebot.lv>
   5
   6 pkgname=dcd
   7 pkgver=0.15.2
   8 pkgrel=1
   9 epoch=1
  10 _pkgcommit=4946d49abdc35810254151923bab30fb3cc2c004
  11 pkgdesc="D Completion Daemon: auto-complete for the D programming language"
  12 arch=('x86_64')
  13 url="https://github.com/dlang-community/DCD"
  14 license=('GPL3')
  15 groups=('dlang')
  16 makedepends=('ldc' 'git')
  17 depends=('liblphobos')
  18 source=("git+https://github.com/dlang-community/DCD#commit=$_pkgcommit"
  19         "git+https://github.com/msgpack/msgpack-d"
  20         "git+https://github.com/dlang-community/libdparse"
  21         "git+https://github.com/dlang-community/d-test-utils"
  22         "git+https://github.com/dlang-community/containers"
  23         "dcd.service"
  24         "dcd.conf")
  25 sha512sums=('SKIP'
  26             'SKIP'
  27             'SKIP'
  28             'SKIP'
  29             'SKIP'
  30             '563e660058721fdacdfa365a774e58b0e9cdb962e14198112a5d971aa4e35025529266130474212834d78ad1c11901e2f8208176a3891ce6ffc9a2ffd9c8c1e0'
  31             '1480d4d66b6732f198fcaae52861b06c8bfcee7f622a546d643a4e8fb259aa0350415fb2f87b1bc4d301ad11af866d7962faf2bcfc0587971a86a73265676703')
  32
  33 prepare() {
  34   cd "$srcdir/DCD"
  35
  36   git submodule init
  37   git config submodule.msgpack-d.url "$srcdir/msgpack-d"
  38   git config submodule.libdparse.url "$srcdir/libdparse"
  39   git config submodule.d-test-utils.url "$srcdir/d-test-utils"
  40   git config submodule.containers.url "$srcdir/containers"
  41   git -c protocol.file.allow=always submodule update
  42
  43   # Only LDC have -O5
  44   sed -i "/-O5/ a -flto=full -linker=gold -link-defaultlib-shared=false -L=\"$LDFLAGS\"\\\\" makefile
  45 }
  46
  47 build() {
  48   cd "$srcdir/DCD"
  49
  50   make ldc
  51 }
  52
  53 package() {
  54   # binaries
  55   install -Dm755 "$srcdir/DCD/bin/dcd-server" "$pkgdir/usr/bin/dcd-server"
  56   install -Dm755 "$srcdir/DCD/bin/dcd-client" "$pkgdir/usr/bin/dcd-client"
  57
  58   # documentation
  59   install -d "$pkgdir/usr/share/man/man1/"
  60   find "$srcdir/DCD/man1/" -type f -exec install -m 644 "{}" "$pkgdir/usr/share/man/man1/" \;
  61
  62   # license
  63   install -Dm644 "$srcdir/DCD/License.txt" "$pkgdir/usr/share/licenses/$pkgname/LICENSE"
  64
  65   # systemd service
  66   install -Dm644 "$srcdir/dcd.service" "$pkgdir/usr/lib/systemd/system/dcd.service"
  67
  68   # global config
  69   install -Dm644 "$srcdir/dcd.conf" "$pkgdir/etc/dcd.conf"
  70 }