dolphin-emu/trunk/PKGBUILD

   1 # Maintainer: schuay <jakob.gruber@gmail.com>
   2 # Maintainer: Maxime Gauduin <alucryd@archlinux.org>
   3 # Contributor: Jeremy Newton (Mystro256) <alexjnewt@gmail.com>
   4
   5 pkgname=dolphin-emu
   6 pkgver=5.0.r18498.46b99671d9
   7 pkgrel=3
   8 epoch=1
   9 pkgdesc='A Gamecube / Wii / Triforce emulator'
  10 arch=(x86_64)
  11 url=https://dolphin-emu.org
  12 license=(GPL2)
  13 depends=(
  14   alsa-lib
  15   bluez-libs
  16   enet
  17   gcc-libs
  18   glibc
  19   hidapi
  20   libavcodec.so
  21   libavformat.so
  22   libavutil.so
  23   libcurl.so
  24   libevdev
  25   libfmt.so
  26   libgl
  27   libmgba
  28   libminiupnpc.so
  29   libpulse
  30   libswscale.so
  31   libudev.so
  32   libusb-1.0.so
  33   libx11
  34   libxi
  35   libxrandr
  36   lzo
  37   #mbedtls
  38   minizip-ng
  39   pugixml
  40   qt6-base
  41   sfml
  42   zlib
  43 )
  44 makedepends=(
  45   cmake
  46   git
  47   ninja
  48   python
  49 )
  50 optdepends=('pulseaudio: PulseAudio backend')
  51 options=(!emptydirs)
  52 _commit=46b99671d9158e0ca840c1d8ef249db0f321ced7
  53 source=(
  54   dolphin-emu::git+https://github.com/dolphin-emu/dolphin.git#commit=${_commit}
  55   git+https://github.com/mozilla/cubeb.git
  56   git+https://github.com/epezent/implot.git
  57   git+https://github.com/randy408/libspng.git
  58   git+https://github.com/RetroAchievements/rcheevos.git
  59   git+https://github.com/arsenm/sanitizers-cmake.git
  60   git+https://github.com/KhronosGroup/SPIRV-Cross.git
  61   git+https://github.com/GPUOpen-LibrariesAndSDKs/VulkanMemoryAllocator.git
  62   git+https://github.com/zlib-ng/zlib-ng.git
  63 )
  64 b2sums=('SKIP'
  65         'SKIP'
  66         'SKIP'
  67         'SKIP'
  68         'SKIP'
  69         'SKIP'
  70         'SKIP'
  71         'SKIP'
  72         'SKIP')
  73
  74 prepare() {
  75   cd dolphin-emu
  76   for submodule in Externals/{cubeb/cubeb,implot/implot,libspng/libspng,spirv_cross/SPIRV-Cross,VulkanMemoryAllocator,zlib-ng/zlib-ng}; do
  77     git submodule init ${submodule}
  78     git config submodule.${submodule}.url ../${submodule##*/}
  79     git -c protocol.file.allow=always submodule update ${submodule}
  80   done
  81   cd Externals/cubeb/cubeb
  82   git submodule init cmake/sanitizers-cmake
  83   git config submodule.cmake/sanitizers-cmake.url "${srcdir}"/sanitizers-cmake
  84   git -c protocol.file.allow=always submodule update cmake/sanitizers-cmake
  85 }
  86
  87 pkgver() {
  88   cd dolphin-emu
  89   git describe | sed 's/-/.r/; s/-g/./'
  90 }
  91
  92 build() {
  93   cmake -S dolphin-emu -B build -G Ninja \
  94     -DCMAKE_BUILD_TYPE=None \
  95     -DCMAKE_INSTALL_PREFIX=/usr \
  96     -DDISTRIBUTOR=archlinux.org \
  97     -DENABLE_TESTS=OFF \
  98     -DUSE_MGBA=ON \
  99     -DUSE_SHARED_ENET=ON \
 100     -Wno-dev
 101   cmake --build build
 102 }
 103
 104 package() {
 105   DESTDIR="${pkgdir}" cmake --install build
 106   install -Dm 644 dolphin-emu/Data/51-usb-device.rules -t "${pkgdir}"/usr/lib/udev/rules.d/
 107   rm -rf "${pkgdir}"/usr/{include,lib/libdiscord-rpc.a}
 108 }
 109
 110 # vim: ts=2 sw=2 et: