dosemu/trunk/PKGBUILD

   1 # Maintainer: Levente Polyak <anthraxx[at]archlinux[dot]org>
   2 # Contributor: Sergej Pupykin <pupykin.s+arch@gmail.com>
   3 # Contributor: Jaroslaw Swierczynski <swiergot@aur.archlinux.org>
   4 # Contributor: Eric Belanger <belanger@astro.umontreal.ca>
   5 # Contributor: Bob Finch <w9ya@arrl.net>
   6
   7 pkgname=dosemu
   8 pkgver=1.4.0.8+753+g18f6f5cd
   9 pkgrel=3
  10 epoch=1
  11 pkgdesc='DOS emulator'
  12 url='http://www.dosemu.org/'
  13 arch=('x86_64')
  14 license=('GPL' 'custom')
  15 depends=('gpm' 'slang' 'sdl' 'libxxf86vm' 'libsndfile' 'alsa-lib')
  16 makedepends=('git' 'xorg-mkfontdir' 'xorg-bdftopcf' 'gendesk' 'imagemagick')
  17 backup=('etc/dosemu/dosemu.conf'
  18         'etc/dosemu/dosemu.users'
  19         'etc/dosemu/global.conf')
  20 source=(${pkgname}::git://git.code.sf.net/p/dosemu/code#commit=18f6f5cdf1beceae8c7532718bfaf423e4a44f6a
  21         https://downloads.sourceforge.net/sourceforge/dosemu/dosemu-freedos-1.0-bin.tgz)
  22 sha512sums=('SKIP'
  23             'd0c4235ceac55de63ce5f72e51b7d57a82b8104f4bf2df6f4dc25c9889d3337b40d75665c2dfc98492ec7123e0959a725f5c7579e145895024bd80a07036e3bd')
  24
  25 pkgver() {
  26   cd ${pkgname}
  27   git describe --tags --always|sed 's/^dosemu-//;s/-/+/g'
  28 }
  29
  30 prepare() {
  31   cd ${pkgname}
  32   gendesk -n \
  33     --pkgname=${pkgname} \
  34     --pkgdesc='dos emulator' \
  35     --categories='system;emulator'
  36 }
  37
  38 build() {
  39   cd ${pkgname}
  40   ./configure \
  41     --prefix=/usr \
  42     --with-fdtarball="${srcdir}/dosemu-freedos-1.0-bin.tgz" \
  43     --mandir=/usr/share/man
  44   make
  45 }
  46
  47 package(){
  48   cd ${pkgname}
  49   make DESTDIR="${pkgdir}" install
  50   install -d "${pkgdir}"/usr/share/pixmaps
  51   convert +set date:create +set date:modify etc/${pkgname}.xpm "${pkgdir}/usr/share/pixmaps/${pkgname}.png"
  52   install -D -m 644 ${pkgname}.desktop -t "${pkgdir}/usr/share/applications"
  53   install -D -m 644 COPYING COPYING.DOSEMU -t "${pkgdir}/usr/share/licenses/${pkgname}"
  54 }
  55
  56 # vim: ts=2 sw=2 et: