dpkg/trunk/PKGBUILD

   1 # Maintainer: Anatol Pomozov
   2 # Contributor: Alad Wenter <alad (at) archlinux.info>
   3 # Contributor: Jochen Schalanda <jochen+aur (at) schalanda.name>
   4 # Contributor: C. Dominik Bódi <dominik.bodi@gmx.de>
   5 # Contributor: Pierre Carrier <pierre@spotify.com>
   6 # Contributor: Thomas Dziedzic <gostrc (at) gmail>
   7 # Contributor: Chris Giles <Chris.G.27 (at) Gmail.com>
   8 # Contributor: seblu <seblu+arch (at) seblu.net>
   9 # Contributor: squiddo <squiddo (at) intheocean.net>
  10 # Contributor: dront78 <dront78 (at) gmail.com>
  11 # Contributor: hugelgupf <ckoch (at) cs.nmt.edu>
  12
  13 pkgname=dpkg
  14 pkgver=1.21.21
  15 pkgrel=1
  16 pkgdesc='The Debian Package Manager tools'
  17 arch=('x86_64')
  18 url="https://tracker.debian.org/pkg/dpkg"
  19 license=('GPL')
  20 options=('emptydirs')
  21 depends=('xz' 'zlib' 'bzip2' 'zstd' 'perl' 'libmd')
  22 makedepends=('perl-io-string' 'perl-timedate' 'git')
  23 checkdepends=('perl-io-string' 'perl-test-pod')
  24 install=dpkg.install
  25 source=(https://salsa.debian.org/dpkg-team/dpkg/-/archive/$pkgver/dpkg-$pkgver.tar.bz2
  26         origin.archlinux)
  27 sha256sums=('1059d38fa421237492275b8d13b5e3d6d1fd20699a01a5b79817ad3e61815787'
  28             '193ac1929ea93157c0173db3c871d2f7fe53385391f48078190b03904c5b1f2d')
  29
  30 prepare() {
  31     cd dpkg-$pkgver
  32     echo "$pkgver" > .dist-version
  33     ./autogen
  34 }
  35
  36 build() {
  37     cd dpkg-$pkgver
  38     CFLAGS+=' -ffat-lto-objects' \
  39     ./configure --prefix=/usr \
  40         --sysconfdir=/etc \
  41         --localstatedir=/var \
  42         --sbindir=/usr/bin \
  43         --libexecdir=/usr/lib \
  44         --disable-start-stop-daemon
  45     make
  46 }
  47
  48 check() {
  49     cd dpkg-$pkgver
  50     # make check
  51 }
  52
  53 package() {
  54     cd dpkg-$pkgver
  55     make DESTDIR="$pkgdir" install
  56     install -Dm644 ../origin.archlinux "$pkgdir"/etc/dpkg/origins/archlinux
  57     ln -sf archlinux "$pkgdir"/etc/dpkg/origins/default
  58
  59     install -d "$pkgdir/var/dpkg"/updates/
  60     touch "$pkgdir/var/lib/dpkg"/{status,available}
  61 }