dra/repos/community-x86_64/PKGBUILD

   1 # Maintainer: Orhun Parmaksız <orhun@archlinux.org>
   2
   3 pkgname=dra
   4 pkgver=0.4.6
   5 pkgrel=1
   6 pkgdesc="A command line tool to download assets from GitHub releases"
   7 arch=('x86_64')
   8 url="https://github.com/devmatteini/dra"
   9 license=('MIT')
  10 depends=('xz' 'zlib' 'bzip2')
  11 makedepends=('cargo')
  12 source=("$pkgname-$pkgver.tar.gz::$url/archive/$pkgver.tar.gz")
  13 sha512sums=('d2bc448090f4080c3056019f4835ca59add810648322343ca55f94043dcccd76e0d422f2a18863552b95f75cdda46d894f8988c27c93ca1e21b7ee8a5882af9a')
  14 options=('!lto')
  15
  16 prepare() {
  17   cd "$pkgname-$pkgver"
  18   cargo fetch --locked --target "$CARCH-unknown-linux-gnu"
  19   mkdir -p completions
  20 }
  21
  22 build() {
  23   cd "$pkgname-$pkgver"
  24   cargo build --release --frozen
  25   local _completion="target/release/$pkgname completion"
  26   $_completion bash > "completions/$pkgname"
  27   $_completion fish > "completions/$pkgname.fish"
  28   $_completion zsh  > "completions/_$pkgname"
  29 }
  30
  31 check() {
  32   cd "$pkgname-$pkgver"
  33   cargo test --frozen --bins
  34 }
  35
  36 package() {
  37   cd "$pkgname-$pkgver"
  38   install -Dm 755 "target/release/$pkgname" -t "$pkgdir/usr/bin"
  39   install -Dm 644 README.md -t "$pkgdir/usr/share/doc/$pkgname"
  40   install -Dm 644 LICENSE -t "$pkgdir/usr/share/licenses/$pkgname"
  41   install -Dm 644 "completions/$pkgname" -t "$pkgdir/usr/share/bash-completion/completions/"
  42   install -Dm 644 "completions/$pkgname.fish" -t "$pkgdir/usr/share/fish/vendor_completions.d/"
  43   install -Dm 644 "completions/_$pkgname" -t "$pkgdir/usr/share/zsh/site-functions/"
  44 }
  45
  46 # vim: ts=2 sw=2 et: