drone-runner-ssh/trunk/PKGBUILD

   1 # Maintainer: George Rawlinson <grawlinson@archlinux.org>
   2
   3 pkgname=drone-runner-ssh
   4 pkgver=1.0.1
   5 pkgrel=4
   6 pkgdesc='Drone runner that executes a pipeline on a remote machine'
   7 arch=('x86_64')
   8 url='https://github.com/drone-runners/drone-runner-ssh'
   9 license=('custom:Polyform-Small-Business-1.0.0' 'custom:Polyform-Free-Trial-1.0.0' 'custom:Polyform-Noncommercial-1.0.0')
  10 depends=('glibc')
  11 makedepends=('git' 'go')
  12 optdepends=('drone: for a local Drone instance')
  13 options=('!lto')
  14 _commit='b5137ad7a32deb15063ec002986af696d9f43b83'
  15 source=(
  16   "$pkgname::git+$url#commit=$_commit"
  17   'systemd.service'
  18   'sysusers.conf'
  19   'tmpfiles.conf'
  20 )
  21 sha512sums=('SKIP'
  22             '6eaa30699fbbaeebaa824add5c1c921e74042d200ae699c393914f3c5f90ae9cdafbd6bbe9d5d555f4914ad9c37ccc897bb0ba65c87dc5fa14b975df0f3da8ab'
  23             'a7d51b61f054bb97f873c7f3e5512776095ed23f9eb5ac9c7a1b007d6595ccc9de0ac4224ca38cdba565bb5ec702c09889e7c7395f03dfb277bb0a5c3225942b'
  24             '239c3eda7cf7ffcac5df80699ec231f2797f4f35b18b26d570303a7597755d1e4958152139ddb3bb5268fe711a1fb055aa97b8d054af13653b0d5f2e35dfb537')
  25 b2sums=('SKIP'
  26         '90d868e9f6932eedc814473e160c661da7cf06a3cf1adf0709b462e388130f3f149120cf36dc6bb9f6bffbca8fce7c8624aa8a0b2511ea64d9b72dc950eea746'
  27         '8459bbc51dd5006159041de20fc8288bed444e9ba8b48d8a95d2f6ea5a89e38e4d1f5db816c2b35f29b3219aba396bff509157a8b234105041d61c3f4504fef6'
  28         'f2742d5c60a3b68ecf7dab2d602b442bafcc619d838fcc74f5f186113778719797f9fa3975643c0925def2acf282c09120c186abc90b1ee5a34a7796b38f00fd')
  29
  30 pkgver() {
  31   cd "$pkgname"
  32
  33   git describe --tags | sed 's/^v//'
  34 }
  35
  36 prepare() {
  37   cd "$pkgname"
  38
  39   # create directory for build output
  40   mkdir -p build
  41
  42   # download dependencies
  43   go mod download
  44 }
  45
  46 build() {
  47   cd "$pkgname"
  48
  49   # set Go flags
  50   export CGO_CPPFLAGS="${CPPFLAGS}"
  51   export CGO_CFLAGS="${CFLAGS}"
  52   export CGO_CXXFLAGS="${CXXFLAGS}"
  53
  54   go build -v \
  55     -trimpath \
  56     -buildmode=pie \
  57     -mod=readonly\
  58     -modcacherw \
  59     -ldflags "-linkmode external -extldflags \"${LDFLAGS}\"" \
  60     -o build \
  61     .
  62 }
  63
  64 check() {
  65   cd "$pkgname"
  66   go test -v ./...
  67 }
  68
  69 package() {
  70   # systemd integration
  71   install -vDm644 systemd.service "$pkgdir/usr/lib/systemd/system/$pkgname.service"
  72   install -vDm644 sysusers.conf "$pkgdir/usr/lib/sysusers.d/$pkgname.conf"
  73   install -vDm644 tmpfiles.conf "$pkgdir/usr/lib/tmpfiles.d/$pkgname.conf"
  74
  75   cd "$pkgname"
  76
  77   # binary
  78   install -vDm755 -t "$pkgdir/usr/bin" build/*
  79
  80   # licenses
  81   install -vDm644 -t "$pkgdir/usr/share/licenses/$pkgname" licenses/* LICENSE.md
  82
  83   # documentation
  84   install -vDm644 -t "$pkgdir/usr/share/doc/$pkgname" README.md CHANGELOG.md
  85 }