dscanner/trunk/PKGBUILD

   1 # Maintainer: Dan Printzell <wild@archlinux.org>
   2 # Maintainer: Filipe Laíns (FFY00) <lains@archlinux.org>
   3
   4 pkgname=dscanner
   5 pkgver=0.14.0
   6 pkgrel=1
   7 _pkgcommit=d5d6920502bf1bfdb29474007a59fd606df0aadc
   8 pkgdesc="Swiss-army knife for D source code"
   9 arch=('x86_64')
  10 url="https://github.com/dlang-community/D-Scanner"
  11 license=("custom")
  12 groups=('dlang')
  13 makedepends=('ldc' 'git')
  14 depends=('liblphobos')
  15 source=("git+https://github.com/dlang-community/D-Scanner#commit=$_pkgcommit"
  16         "git+https://github.com/dlang-community/libdparse"
  17         "git+https://github.com/burner/inifiled"
  18         "git+https://github.com/dlang-community/containers"
  19         "git+https://github.com/dlang-community/libddoc"
  20         "git+https://github.com/dlang-community/d-test-utils"
  21         "git+https://github.com/dlang-community/DCD")
  22 sha512sums=('SKIP'
  23             'SKIP'
  24             'SKIP'
  25             'SKIP'
  26             'SKIP'
  27             'SKIP'
  28             'SKIP')
  29
  30 prepare() {
  31   cd "$srcdir/D-Scanner"
  32
  33   git submodule init
  34   git config submodule.libdparse.url "$srcdir/libdparse"
  35   git config submodule.inifiled.url "$srcdir/inifiled"
  36   git config submodule.containers.url "$srcdir/containers"
  37   git config submodule.libddoc.url "$srcdir/libddoc"
  38   git config submodule.d-test-utils.url "$srcdir/d-test-utils"
  39   git config submodule.DCD.url "$srcdir/DCD"
  40   git -c protocol.file.allow=always submodule update
  41
  42   # Only LDC have -O5, and add DC_FLAGS to linking
  43   sed -i -e "s/-O5/-O5 -flto=full -link-defaultlib-shared=false -L=\"$LDFLAGS\"/g" -e 's/OBJ_BY_DC} \${WRITE_TO_TARGET_NAME}/OBJ_BY_DC} ${WRITE_TO_TARGET_NAME} ${DC_FLAGS}/' makefile
  44 }
  45
  46 build() {
  47   cd "$srcdir/D-Scanner"
  48   DC=ldc2 make
  49 }
  50
  51 package() {
  52   # binaries
  53   install -Dm755 "$srcdir/D-Scanner/bin/dscanner" "$pkgdir/usr/bin/dscanner"
  54
  55   # license
  56   install -Dm644 "$srcdir/D-Scanner/LICENSE_1_0.txt" "$pkgdir/usr/share/licenses/$pkgname/LICENSE"
  57 }