eolie/repos/community-any/PKGBUILD

   1 # Maintainer: Balló György <ballogyor+arch at gmail dot com>
   2 # Contributor: Cédric Bellegarde cedric bellegarde at adishatz dot org
   3
   4 pkgname=eolie
   5 pkgver=0.9.101
   6 pkgrel=4
   7 pkgdesc='Simple web browser for GNOME'
   8 arch=('any')
   9 url='https://wiki.gnome.org/Apps/Eolie'
  10 license=('GPL3')
  11 depends=('gnome-settings-daemon' 'gtkspell3' 'libhandy' 'python-cairo' 'python-gobject' 'webkit2gtk')
  12 makedepends=('git' 'gobject-introspection' 'meson')
  13 optdepends=('python-beautifulsoup4: Import HTML bookmarks'
  14             'python-fxa: Firefox Sync support'
  15             'python-pycryptodome: Firefox Sync support'
  16             'python-pyopenssl: Show SSL certificates'
  17             'python-requests-hawk: Firefox Sync support')
  18 _commit=168b669f0bccdf41ccabfbd380af685e812f9384  # tags/0.9.101
  19 source=("git+https://gitlab.gnome.org/World/eolie.git#commit=$_commit"
  20         "git+https://gitlab.gnome.org/gnumdk/eolie-po.git")
  21 sha256sums=('SKIP'
  22             'SKIP')
  23
  24 pkgver() {
  25   cd $pkgname
  26   git describe --tags | sed 's/-/+/g'
  27 }
  28
  29 prepare() {
  30   cd $pkgname
  31   git config submodule.subprojects/po.url "$srcdir/eolie-po"
  32   git -c protocol.file.allow=always submodule update --init
  33 }
  34
  35 build() {
  36   arch-meson $pkgname build
  37   meson compile -C build
  38 }
  39
  40 check() {
  41   meson test -C build --print-errorlogs
  42 }
  43
  44 package() {
  45   meson install -C build --destdir "$pkgdir"
  46 }