espflash/trunk/PKGBUILD

   1 # Maintainer: kpcyrd <kpcyrd[at]archlinux[dot]org>
   2
   3 pkgbase=espflash
   4 pkgname=(espflash cargo-espflash)
   5 pkgver=1.7.0
   6 pkgrel=3
   7 pkgdesc="Cargo subcommand for flashing Espressif devices over serial"
   8 url='https://github.com/esp-rs/espflash'
   9 arch=('x86_64')
  10 license=('MIT' 'Apache-2.0')
  11 depends=('libudev.so' 'libuv')
  12 makedepends=('cargo' 'udev')
  13 options=(!lto)
  14 source=(https://github.com/esp-rs/${pkgbase}/archive/v${pkgver}/${pkgbase}-${pkgver}.tar.gz)
  15 sha256sums=('3efdbcc6edeaadd4beca9c685a24486ee14729b3f638e963363328c95c89f1a3')
  16 b2sums=('e7fb0b8abc7f0c6e0fd82b8b4b035174eb8ec56f9578d3d5b5f2477b5a1eac23cc68984f7bd147ae8e1df08b50b3de1ce055ca94f5e1b0df22b030fa5483e900')
  17
  18 prepare() {
  19   cd ${pkgbase}-${pkgver}
  20   cargo fetch --locked --target "$CARCH-unknown-linux-gnu"
  21 }
  22
  23 build() {
  24   cd ${pkgbase}-${pkgver}
  25   cargo build --frozen --release
  26 }
  27
  28 check() {
  29   cd ${pkgbase}-${pkgver}
  30   cargo test --frozen --workspace
  31 }
  32
  33 package_espflash() {
  34   cd ${pkgbase}-${pkgver}
  35   install -Dm 755 -t "${pkgdir}/usr/bin" \
  36     target/release/espflash
  37 }
  38
  39 package_cargo-espflash() {
  40   cd ${pkgbase}-${pkgver}
  41   install -Dm 755 -t "${pkgdir}/usr/bin" \
  42     target/release/cargo-espflash
  43 }
  44
  45 # vim: ts=2 sw=2 et: