fisher/trunk/PKGBUILD

   1 # Maintainer: George Rawlinson <grawlinson@archlinux.org>
   2 # Contributor: Sefa Eyeoglu <contact@scrumplex.net>
   3 # Contributor: Daniel Maslowski <info@orangecms.org>
   4
   5 pkgname=fisher
   6 pkgver=4.4.3
   7 pkgrel=1
   8 pkgdesc='A package manager for the fish shell'
   9 arch=('any')
  10 url='https://github.com/jorgebucaran/fisher'
  11 license=('MIT')
  12 depends=('fish' 'curl')
  13 makedepends=('git')
  14 # TODO add fishtape for tests
  15 _commit='36810b39401536650d7a1018c8f3832f51741950'
  16 source=("$pkgname::git+$url#commit=$_commit")
  17 b2sums=('SKIP')
  18
  19 pkgver() {
  20   cd "$pkgname"
  21
  22   git describe --tags | sed 's/^v//'
  23 }
  24
  25 package() {
  26   cd "$pkgname"
  27
  28   # install to global fish directory
  29   install -vDm644 -t "$pkgdir/usr/share/fish/vendor_functions.d" functions/fisher.fish
  30   install -vDm644 -t "$pkgdir/usr/share/fish/vendor_completions.d" completions/fisher.fish
  31
  32   # documentation
  33   install -vDm644 -t "$pkgdir/usr/share/doc/$pkgname" README.md
  34
  35   # license
  36   install -vDm644 -t "$pkgdir/usr/share/licenses/$pkgname" LICENSE.md
  37 }