fq/trunk/PKGBUILD

   1 # Maintainer: Orhun Parmaksız <orhun@archlinux.org>
   2 # Maintainer: Caleb Maclennan <caleb@alerque.com>
   3 # Contributor: Daniel Milde <daniel at milde dot cz>
   4
   5 pkgname=fq
   6 pkgver=0.6.0
   7 pkgrel=1
   8 pkgdesc="Tool, language and decoders for inspecting binary data"
   9 arch=('x86_64')
  10 url="https://github.com/wader/fq"
  11 license=('MIT')
  12 depends=('glibc')
  13 checkdepends=('expect')
  14 makedepends=('go' 'git')
  15 source=("${url}/archive/v${pkgver}/${pkgname}-${pkgver}.tar.gz")
  16 sha256sums=('a3f21161fdbe1e258fbc84cb88d1ec5192c6d019c497da5e8a69a2f549088f01')
  17
  18 prepare() {
  19   cd "${pkgname}-${pkgver}"
  20   mkdir -p dist/
  21 }
  22
  23 build() {
  24   cd "${pkgname}-${pkgver}"
  25   go build \
  26     -trimpath \
  27     -buildmode=pie \
  28     -mod=readonly \
  29     -modcacherw \
  30     -ldflags "-linkmode external -extldflags \"${LDFLAGS}\" ${_BUILDINFO}" \
  31     -o dist/fq \
  32     .
  33 }
  34
  35 check() {
  36   cd "${pkgname}-${pkgver}"
  37   make test
  38 }
  39
  40 package() {
  41   cd "${pkgname}-${pkgver}"
  42   install -Dm 755 "dist/${pkgname}" -t "${pkgdir}/usr/bin"
  43   install -Dm 644 LICENSE  -t "${pkgdir}/usr/share/licenses/${pkgname}"
  44   install -Dm 644 README.md -t "${pkgdir}/usr/share/doc/${pkgname}"
  45 }
  46
  47 # vim:set ts=2 sw=2 et: