genact/repos/community-x86_64/PKGBUILD

   1 # Maintainer: Sven-Hendrik Haase <svenstaro@archlinux.org>
   2 pkgname=genact
   3 pkgver=1.2.2
   4 pkgrel=1
   5 pkgdesc="A nonsense activity generator"
   6 url="https://github.com/svenstaro/genact"
   7 arch=("x86_64")
   8 license=("MIT")
   9 depends=('gcc-libs')
  10 makedepends=("rust")
  11 source=("$pkgname-$pkgver.tar.gz::https://github.com/svenstaro/$pkgname/archive/v$pkgver.tar.gz")
  12 sha512sums=('059c86a260e405cd6848f95e1e507a38a58d73eea392211757eb48d6e087d80c13480cea69a9b4d6266278edc9ca5eff51eb24553fa67b4310b68693528cf5f1')
  13
  14 build() {
  15     cd "$srcdir/$pkgname-$pkgver"
  16
  17     cargo build --release --locked
  18 }
  19
  20 package() {
  21     cd "$srcdir/$pkgname-$pkgver"
  22
  23     install -Dm755 target/release/$pkgname "$pkgdir"/usr/bin/$pkgname
  24
  25     mkdir -p "$pkgdir"/usr/share/{bash-completion/completions,zsh/site-functions,fish/vendor_completions.d}
  26     target/release/$pkgname --print-completions bash > "$pkgdir"/usr/share/bash-completion/completions/$pkgname
  27     target/release/$pkgname --print-completions zsh > "$pkgdir"/usr/share/zsh/site-functions/_$pkgname
  28     target/release/$pkgname --print-completions fish > "$pkgdir"/usr/share/fish/vendor_completions.d/$pkgname.fish
  29
  30     mkdir -p "$pkgdir"/usr/share/man/man1
  31     target/release/$pkgname --print-manpage | gzip > "$pkgdir"/usr/share/man/man1/$pkgname.1.gz
  32
  33     install -Dm644 LICENSE "$pkgdir"/usr/share/licenses/$pkgname/LICENSE
  34 }