gimp-nufraw/repos/community-x86_64/PKGBUILD

   1 # Maintainer: Christian Hesse <mail@eworm.de>
   2
   3 pkgname=gimp-nufraw
   4 _realver=0.43-3
   5 pkgver=0.43.3
   6 pkgrel=7
   7 pkgdesc='Converter for raw files; utility and GIMP plugin'
   8 url='https://sourceforge.net/projects/nufraw/'
   9 arch=('x86_64')
  10 license=('GPL')
  11 depends=('cfitsio' 'exiv2' 'gtkimageview' 'lcms2' 'lensfun' 'libjpeg-turbo')
  12 makedepends=('gimp')
  13 conflicts=('gimp-ufraw')
  14 replaces=('gimp-ufraw')
  15 optdepends=('gimp: to use the gimp import plugin for raw images')
  16 source=("https://downloads.sourceforge.net/nufraw/nufraw-${_realver}.tar.gz"
  17          nufraw-glib-2.70.patch)
  18 sha256sums=('2c7dcc1590993ec267b3112562b2433010d6f94f6acc6506c76aa29cf8c6c32c'
  19             '0e422f77b277f3c38b454426ee155d1004e47ced8d5d05942448584557c9ed07')
  20
  21 prepare() {
  22   cd "nufraw-${_realver}"
  23
  24   patch -p1 < ../nufraw-glib-2.70.patch # Fix build with glib 2.70
  25
  26   autoreconf -fi
  27
  28   mv nufraw.desktop{.desktop,}
  29   chmod +x generate_schemas.sh
  30 }
  31
  32 build() {
  33   cd "nufraw-${_realver}"
  34
  35   ./configure \
  36     --prefix=/usr \
  37     --enable-extras \
  38     --enable-mime \
  39     --enable-openmp \
  40     --with-gimp \
  41     --with-cinepaint \
  42     --enable-contrast
  43   make
  44 }
  45
  46 package() {
  47   make -C "nufraw-${_realver}" DESTDIR="$pkgdir" install
  48   rm -f "$pkgdir/usr/bin/dcraw"
  49 }