gitlab-workhorse/trunk/PKGBUILD

   1 # Maintainer: Sven-Hendrik Haase <svenstaro@gmail.com>
   2 # Contributor: Caleb Maclennan <caleb@alerque.com>
   3 # Contributor: Pavol (Lopo) Hluchy <lopo AT losys DOT eu>
   4
   5 pkgname=gitlab-workhorse
   6 pkgver=8.65.0
   7 pkgrel=1
   8 pkgdesc="A smart reverse proxy for GitLab that handles large HTTP requests such as file downloads, file uploads, git push/pull and git archive downloads"
   9 arch=('x86_64')
  10 url="https://gitlab.com/gitlab-org/gitlab-workhorse"
  11 license=('MIT')
  12 depends=('glibc' 'perl-image-exiftool')
  13 makedepends=('go')
  14 source=("${pkgname}-${pkgver}.tar.gz::https://gitlab.com/api/v4/projects/gitlab-org%2Fgitlab-workhorse/repository/archive?sha=v${pkgver}"
  15         "gitlab-workhorse.service")
  16 sha512sums=('724f8901bc3fb93cbe40104d4b5e5072dcf24b81b5520fbe91b6b2c91b9ff869edf6398acbf9d04a2c95a19b50888c975552fd1f369cc4787eb8dc78bf2eded6'
  17             '893527f270179fc78ff60e33f0b44abd984d1e9859dd5bf59fea77245ddd4c1c252d2c7882719366944d0f9341a90b5e077470b15afcc3df419b0d0a9f2e6d56')
  18
  19 build() {
  20   cd "${pkgname}-v${pkgver}-"*
  21
  22   export CGO_CPPFLAGS="${CPPFLAGS}"
  23   export CGO_CFLAGS="${CFLAGS}"
  24   export CGO_CXXFLAGS="${CXXFLAGS}"
  25   export CGO_LDFLAGS="${LDFLAGS}"
  26   export GOFLAGS="-buildmode=pie -trimpath -mod=readonly -modcacherw"
  27   make
  28 }
  29
  30 package() {
  31   cd "${pkgname}-v${pkgver}-"*
  32
  33   install -Dm755 "gitlab-workhorse" "${pkgdir}/usr/bin/gitlab-workhorse"
  34   install -Dm755 "gitlab-zip-cat" "${pkgdir}/usr/bin/gitlab-zip-cat"
  35   install -Dm755 "gitlab-zip-metadata" "${pkgdir}/usr/bin/gitlab-zip-metadata"
  36   install -Dm644 "LICENSE" "${pkgdir}/usr/share/licenses/${pkgname}/LICENSE"
  37   install -Dm0644 "${srcdir}/gitlab-workhorse.service" "${pkgdir}/usr/lib/systemd/system/gitlab-workhorse.service"
  38 }