glabels/repos/community-x86_64/PKGBUILD

   1 # Maintainer: Balló György <ballogyor+arch at gmail dot com>
   2 # Contributor: yugrotavele <yugrotavele at archlinux dot us>
   3 # Contributor: Damir Perisa <damir@archlinux.org>
   4
   5 pkgname=glabels
   6 pkgver=3.4.1
   7 pkgrel=9
   8 pkgdesc='Creating labels and business cards the very easy way'
   9 arch=('x86_64')
  10 url='https://gitlab.gnome.org/Archive/glabels'
  11 license=('GPL3')
  12 depends=('evolution-data-server' 'iec16022' 'qrencode')
  13 makedepends=('intltool' 'itstool' 'python')
  14 source=("https://download.gnome.org/sources/$pkgname/${pkgver%.*}/$pkgname-$pkgver.tar.xz")
  15 sha256sums=('18e457298abb1c617187361109eeae769317686303fc07726af31e11519c5938')
  16
  17 prepare() {
  18   cd $pkgname-$pkgver
  19   sed -i 's|appdatadir = $(datadir)/appdata|appdatadir = $(datadir)/metainfo|' data/appdata/Makefile.{am,in}
  20 }
  21
  22 build() {
  23   cd $pkgname-$pkgver
  24   CFLAGS+=" -fcommon"
  25   ./configure --prefix=/usr --disable-schemas-compile
  26   sed -i -e 's/ -shared / -Wl,-O1,--as-needed\0/g' libtool
  27   make
  28 }
  29
  30 package() {
  31   cd $pkgname-$pkgver
  32   make DESTDIR="$pkgdir" install
  33 }