gloobus-preview/trunk/PKGBUILD

   1 # Maintainer: Balló György <ballogyor+arch at gmail dot com>
   2
   3 pkgname=gloobus-preview
   4 _bzrrev=336
   5 pkgver=0.4.5.$_bzrrev
   6 pkgrel=5
   7 pkgdesc="GNOME application designed to enable a full screen preview of any kind of file"
   8 arch=('x86_64')
   9 url="https://launchpad.net/gloobus-preview"
  10 license=('GPL')
  11 depends=('gst-plugins-base' 'gtksourceview3' 'poppler-glib' 'python-dbus' 'python-gobject')
  12 makedepends=('boost' 'bzr' 'djvulibre' 'libgxps' 'libspectre')
  13 optdepends=('djvulibre: Preview DjVu documents'
  14             'gst-libav: Extra media codecs'
  15             'gst-plugins-bad: Extra media codecs'
  16             'gst-plugins-good: Extra media codecs'
  17             'gst-plugins-ugly: Extra media codecs'
  18             'imagemagick: Support for more image formats'
  19             'libgxps: Preview XPS documents'
  20             'libspectre: Preview PostScript documents'
  21             'unoconv: Preview LibreOffice compatible documents')
  22 source=(bzr+lp:$pkgname#revision=$_bzrrev)
  23 sha256sums=('SKIP')
  24
  25 prepare() {
  26   cd $pkgname
  27   sed -i '/ACX_PTHREAD()/d' configure.ac
  28   autoreconf -vi
  29 }
  30
  31 build() {
  32   cd $pkgname
  33   ./configure --prefix=/usr
  34
  35   #https://bugzilla.gnome.org/show_bug.cgi?id=656231
  36   sed -i -e 's/ -shared / -Wl,-O1,--as-needed\0/g' libtool
  37
  38   make
  39 }
  40
  41 package() {
  42   cd $pkgname
  43   make DESTDIR="$pkgdir" install
  44 }