gnome-mplayer/trunk/PKGBUILD

   1 # Maintainer: Balló György <ballogyor+arch at gmail dot com>
   2 # Contributor: Lukas Fleischer <lfleischer@archlinux.org>
   3 # Contributor: Allan McRae <mcrae_allan@hotmail.com>
   4 # Contributor: Daniel J Griffiths <ghost1227@archlinux.us>
   5
   6 pkgname=gnome-mplayer
   7 pkgver=1.0.9
   8 pkgrel=8
   9 pkgdesc='GTK/Gnome interface around MPlayer'
  10 arch=('x86_64')
  11 url='https://sites.google.com/site/kdekorte2/gnomemplayer'
  12 license=('GPL')
  13 depends=('dbus-glib' 'gmtk' 'libgda' 'libgpod' 'libnotify')
  14 makedepends=('caja' 'nautilus' 'nemo' 'python')
  15 optdepends=('caja: file manager integration for Caja'
  16             'nautilus: file manager integration for Nautilus'
  17             'nemo: file manager integration for Nemo')
  18 source=("https://github.com/kdekorte/$pkgname/archive/v$pkgver/$pkgname-$pkgver.tar.gz"
  19         'gnome-mplayer.appdata.xml'
  20         'caja.patch')
  21 sha256sums=('07e11bc42834dae14ad66f887e6045f2bea94eae7f797b624c9a099f806b5cde'
  22             '2e661347fa2765a9553938db9582a833b42385db92f6687172507deecf404567'
  23             '52dbf11e64042c03ec94677ee667d88306f5f45521b7a1da82e5e5f02f59ed28')
  24
  25 prepare() {
  26   cd $pkgname-$pkgver
  27   patch -Np0 -i ../caja.patch
  28   sed -i 's/Exec=gnome-mplayer %U/Exec=gnome-mplayer %F/' $pkgname.desktop
  29   sed -i '/AM_GCONF_SOURCE_2/d' configure.in
  30   autoreconf -fi
  31 }
  32
  33 build() {
  34   cd $pkgname-$pkgver
  35   CFLAGS+=' -fcommon' # https://wiki.gentoo.org/wiki/Gcc_10_porting_notes/fno_common
  36   ./configure --prefix=/usr
  37   make
  38 }
  39
  40 package() {
  41   cd $pkgname-$pkgver
  42   make DESTDIR="$pkgdir" install
  43   install -Dm644 ../gnome-mplayer.appdata.xml "$pkgdir/usr/share/metainfo/gnome-mplayer.appdata.xml"
  44 }