gnuradio-osmosdr/repos/community-x86_64/PKGBUILD

   1 # Maintainer: Kyle Keen <keenerd@gmail.com?>
   2 # Contributor: Dominik Heidler <dheidler@gmail.com>
   3
   4 _name=gr-osmosdr
   5 pkgname=gnuradio-osmosdr
   6 pkgver=0.2.4
   7 _commit=09257669f52605e2dad71e4035d7a3d73121ac68  # refs/tags/v0.2.4
   8 pkgrel=5
   9 pkgdesc='Source block for Funcube Dongle, RTL-SDR, USRP, OsmoSDR, BladeRF, HackRF and AirSpy devices'
  10 url='https://osmocom.org/projects/gr-osmosdr'
  11 arch=(x86_64)
  12 license=(GPL3)
  13 depends=(
  14   airspy
  15   bladerf
  16   gcc-libs
  17   glibc
  18   hackrf
  19   libuhd
  20   libvolk
  21   soapysdr
  22   rtl-sdr
  23 )
  24 makedepends=(
  25   cmake
  26   boost
  27   git
  28   gnuradio
  29   gnuradio-iqbal
  30   pybind11
  31 )
  32 optdepends=('python-opengl: for osmocom_fft')
  33 provides=(libgnuradio-osmosdr.so)
  34 replaces=('gr-osmosdr')
  35 source=(git+https://gitea.osmocom.org/sdr/$_name.git#tag=$_commit)
  36 sha256sums=('SKIP')
  37
  38 build() {
  39   local cmake_options=(
  40     -B build
  41     -D CMAKE_BUILD_TYPE=None
  42     -D CMAKE_INSTALL_PREFIX=/usr
  43     -D Boost_NO_BOOST_CMAKE=ON
  44     -D ENABLE_AIRSPY=ON
  45     # -D ENABLE_AIRSPYHF=ON  # TODO: package https://github.com/airspy/airspyhf
  46     -D ENABLE_BLADERF=ON
  47     # -D ENABLE_FCD=ON  # TODO: package https://github.com/dl1ksv/gr-funcube
  48     -D ENABLE_FILE=ON
  49     # -D ENABLE_FREESRP=ON  # TODO: package https://github.com/myriadrf/libfreesrp
  50     -D ENABLE_HACKRF=ON
  51     -D ENABLE_IQBALANCE=ON
  52     # -D ENABLE_MIRI=ON  # TODO: package https://gitea.osmocom.org/sdr/libmirisdr
  53     -D ENABLE_PYTHON=ON
  54     -D ENABLE_REDPITAYA=ON
  55     -D ENABLE_RFSPACE=ON
  56     -D ENABLE_RTL=ON
  57     -D ENABLE_RTL_TCP=ON
  58     -D ENABLE_SOAPY=ON
  59     -D ENABLE_UHD=ON
  60     # -D ENABLE_XTRX=ON  # TODO: package https://github.com/xtrx-sdr/libxtrx
  61     -S $_name
  62     -W no-dev
  63   )
  64
  65   cmake "${cmake_options[@]}"
  66   cmake --build build
  67 }
  68
  69 package() {
  70   depends+=(
  71     boost-libs libboost_{chrono,thread}.so
  72     gnuradio libgnuradio-{blocks,runtime,pmt,uhd}.so
  73     gnuradio-iqbal libgnuradio-iqbalance.so
  74   )
  75
  76   DESTDIR="$pkgdir" cmake --install build
  77 }