gopass-summon-provider/repos/community-x86_64/PKGBUILD

   1 # Maintainer: christian rebischke <chris.rebischke@archlinux.org>
   2
   3 pkgname=gopass-summon-provider
   4 pkgver=1.12.0
   5 pkgrel=2
   6 pkgdesc="summon provider for gopass"
   7 arch=('x86_64')
   8 url="https://github.com/gopasspw/gopass-summon-provider"
   9 license=('MIT')
  10 depends=('glibc')
  11 makedepends=('go')
  12 options=('!lto')
  13 source=("${pkgname}-${pkgver}.tar.gz::https://github.com/gopasspw/gopass-summon-provider/archive/refs/tags/v${pkgver}.tar.gz")
  14 sha512sums=('2ffb41d53cc370feb2c5c75c5a13680035f44b4432e092f84b977cfc62cbcb60e94eb2d3b2da931f647fed30bff3086397f044de34eb3010efb307662a48f23a')
  15
  16 prepare(){
  17   cd ${pkgname}-${pkgver}
  18   sed -i 's|-gcflags="-trimpath=$(GOPATH)" -asmflags="-trimpath=$(GOPATH)"||' Makefile
  19   sed -i 's/install-completion//g' Makefile
  20 }
  21
  22 build(){
  23   cd ${pkgname}-${pkgver}
  24   export CGO_CPPFLAGS="${CPPFLAGS}"
  25   export CGO_CFLAGS="${CFLAGS}"
  26   export CGO_CXXFLAGS="${CXXFLAGS}"
  27   export CGO_LDFLAGS="${LDFLAGS}"
  28   export GOFLAGS="-buildmode=pie -trimpath -mod=readonly -modcacherw"
  29   make
  30 }
  31
  32 package() {
  33   cd ${pkgname}-${pkgver}
  34   make DESTDIR="${pkgdir}" PREFIX="/usr" install
  35   install -Dm644 LICENSE "${pkgdir}/usr/share/licenses/${pkgname}/LICENSE"
  36 }