gpg-tui/trunk/PKGBUILD

   1 # Maintainer: Orhun Parmaksız <orhun@archlinux.org>
   2
   3 pkgname=gpg-tui
   4 pkgver=0.9.5
   5 pkgrel=1
   6 pkgdesc="A terminal user interface for GnuPG"
   7 arch=('x86_64')
   8 url="https://github.com/orhun/gpg-tui"
   9 license=('MIT')
  10 depends=('libxcb' 'libxkbcommon' 'gpgme')
  11 makedepends=('cargo' 'python')
  12 optdepends=(
  13   'xplr: for file selection support'
  14   'xclip: for clipboard support on X11 (or xsel)'
  15   'xsel: for clipboard support on X11 (or xclip)'
  16   'wl-clipboard: for clipboard support on Wayland'
  17 )
  18 source=("$pkgname-$pkgver.tar.gz::$url/archive/v$pkgver.tar.gz")
  19 sha512sums=('d1f38886175bec44cfaecfdb8960024ce15ff728ba95012cf255bf03f22e6b07aafa2d632b6cb7ae4c95c3213981a13a30cdf22235471e83c33d9f3d8aab5206')
  20
  21 prepare() {
  22   cd "$pkgname-$pkgver"
  23   mkdir completions/
  24   cargo fetch --locked --target "$CARCH-unknown-linux-gnu"
  25 }
  26
  27 build() {
  28   cd "$pkgname-$pkgver"
  29   cargo build --release --frozen
  30   OUT_DIR=completions/ target/release/gpg-tui-completions
  31 }
  32
  33 check() {
  34   cd "$pkgname-$pkgver"
  35   cargo test --frozen
  36 }
  37
  38 package() {
  39   cd "$pkgname-$pkgver"
  40   install -Dm 755 "target/release/$pkgname" -t "$pkgdir/usr/bin"
  41   install -Dm 644 README.md -t "$pkgdir/usr/share/doc/$pkgname"
  42   install -Dm 644 LICENSE -t "$pkgdir/usr/share/licenses/$pkgname"
  43   install -Dm 644 "man/$pkgname.1" -t "$pkgdir/usr/share/man/man1"
  44   install -Dm 644 "man/$pkgname.toml.5" -t "$pkgdir/usr/share/man/man5"
  45   install -Dm 644 "completions/$pkgname.bash" "$pkgdir/usr/share/bash-completion/completions/$pkgname"
  46   install -Dm 644 "completions/$pkgname.fish" -t "$pkgdir/usr/share/fish/vendor_completions.d"
  47   install -Dm 644 "completions/_$pkgname" -t "$pkgdir/usr/share/zsh/site-functions"
  48 }
  49
  50 # vim: ts=2 sw=2 et: