grex/trunk/PKGBUILD

   1 # Maintainer: Orhun Parmaksız <orhun@archlinux.org>
   2 # Contributor: Martin Mariano <arch@martinmariano.com>
   3
   4 pkgname=grex
   5 pkgver=1.4.1
   6 pkgrel=1
   7 pkgdesc="A command-line tool for generating regular expressions from user-provided input strings"
   8 arch=('x86_64')
   9 url="https://github.com/pemistahl/grex"
  10 license=('Apache')
  11 depends=('gcc-libs')
  12 makedepends=('cargo')
  13 source=("$pkgname-$pkgver.tar.gz::$url/archive/v$pkgver.tar.gz")
  14 sha512sums=('3a636bf2df62b876de2f44366a402ab89547d57503836e0d0fc205d5032c0981b34f44619daecd27eb2229fba44f3365bfeeab6a5f8f613b78435643a35a1012')
  15
  16 prepare() {
  17   cd "$pkgname-$pkgver"
  18   cargo fetch --locked --target "$CARCH-unknown-linux-gnu"
  19 }
  20
  21 build() {
  22   cd "$pkgname-$pkgver"
  23   cargo build --frozen --release
  24 }
  25
  26 check() {
  27   cd "$pkgname-$pkgver"
  28   cargo test --frozen
  29 }
  30
  31 package() {
  32   cd "$pkgname-$pkgver"
  33   install -Dm 755 "target/release/$pkgname" -t "$pkgdir/usr/bin"
  34   install -Dm 644 README.md -t "$pkgdir/usr/share/doc/$pkgname"
  35 }
  36
  37 # vim: ts=2 sw=2 et: