haskell-gtk-sni-tray/trunk/PKGBUILD

   1 # Maintainer: Felix Yan <felixonmars@archlinux.org>
   2
   3 _hkgname=gtk-sni-tray
   4 pkgname=haskell-gtk-sni-tray
   5 pkgver=0.1.8.1
   6 pkgrel=83
   7 pkgdesc="A standalone StatusNotifierItem/AppIndicator tray"
   8 url="https://github.com/IvanMalison/gtk-sni-tray#readme"
   9 license=("BSD")
  10 arch=('x86_64')
  11 depends=('ghc-libs' 'haskell-dbus' 'haskell-dbus-hslogger' 'haskell-enclosed-exceptions'
  12          'haskell-gi-cairo' 'haskell-gi-cairo-connector' 'haskell-gi-cairo-render'
  13          'haskell-gi-dbusmenugtk3' 'haskell-gi-gdk3' 'haskell-gi-gdkpixbuf' 'haskell-gi-glib'
  14          'haskell-gi-gtk3' 'haskell-gtk-strut' 'haskell-gi' 'haskell-gi-base' 'haskell-hslogger'
  15          'haskell-optparse-applicative' 'haskell-status-notifier-item' 'haskell-transformers-base'
  16          'gtk3')
  17 makedepends=('ghc')
  18 source=("https://hackage.haskell.org/packages/archive/$_hkgname/$pkgver/$_hkgname-$pkgver.tar.gz")
  19 sha256sums=('ce977bb551bbd4a1898e43ad6c3cf8bd95181ec46e31a81c7b53956af40c2344')
  20
  21 build() {
  22   cd $_hkgname-$pkgver
  23
  24   runhaskell Setup configure -O --enable-shared --enable-executable-dynamic --disable-library-vanilla \
  25     --prefix=/usr --docdir=/usr/share/doc/$pkgname --datasubdir=$pkgname --enable-tests \
  26     --dynlibdir=/usr/lib --libsubdir=\$compiler/site-local/\$pkgid --ghc-option=-fllvm \
  27     --ghc-option=-optl-Wl\,-z\,relro\,-z\,now \
  28     --ghc-option='-pie'
  29
  30   runhaskell Setup build $MAKEFLAGS
  31   runhaskell Setup register --gen-script
  32   runhaskell Setup unregister --gen-script
  33   sed -i -r -e "s|ghc-pkg.*update[^ ]* |&'--force' |" register.sh
  34   sed -i -r -e "s|ghc-pkg.*unregister[^ ]* |&'--force' |" unregister.sh
  35 }
  36
  37 check() {
  38   cd $_hkgname-$pkgver
  39   runhaskell Setup test --show-details=direct
  40 }
  41
  42 package() {
  43   cd $_hkgname-$pkgver
  44
  45   install -D -m744 register.sh "$pkgdir"/usr/share/haskell/register/$pkgname.sh
  46   install -D -m744 unregister.sh "$pkgdir"/usr/share/haskell/unregister/$pkgname.sh
  47   runhaskell Setup copy --destdir="$pkgdir"
  48   install -D -m644 LICENSE -t "$pkgdir"/usr/share/licenses/$pkgname/
  49   rm -f "$pkgdir"/usr/share/doc/$pkgname/LICENSE
  50 }