haskell-hls-explicit-imports-plugin/trunk/PKGBUILD

   1 # Maintainer: Felix Yan <felixonmars@archlinux.org>
   2
   3 _hkgname=hls-explicit-imports-plugin
   4 pkgname=haskell-hls-explicit-imports-plugin
   5 pkgver=1.2.0.0
   6 pkgrel=15
   7 pkgdesc="Explicit imports plugin for Haskell Language Server"
   8 url="https://hackage.haskell.org/package/hls-explicit-imports-plugin"
   9 license=("Apache")
  10 arch=('x86_64')
  11 depends=('ghc-libs' 'haskell-aeson' 'haskell-ghc' 'haskell-ghcide' 'haskell-hls-graph'
  12          'haskell-hls-plugin-api' 'haskell-lsp' 'haskell-unordered-containers')
  13 makedepends=('ghc' 'uusi' 'haskell-hls-test-utils')
  14 checkdepends=('git')
  15 source=("https://hackage.haskell.org/packages/archive/$_hkgname/$pkgver/$_hkgname-$pkgver.tar.gz")
  16 sha512sums=('b4e52b974c0a79ce43bfb4a5a6252a5f5adf06bbf5fbecdc80aa14d359042471381b44fb2f810bbdaa0e687dc828f4a08b71c76fa088de18b9d1e8e23aa562cd')
  17
  18 prepare() {
  19   cd $_hkgname-$pkgver
  20   gen-setup
  21 }
  22
  23 build() {
  24   cd $_hkgname-$pkgver
  25
  26   runhaskell Setup configure -O --enable-shared --enable-executable-dynamic --disable-library-vanilla \
  27     --prefix=/usr --docdir=/usr/share/doc/$pkgname --datasubdir=$pkgname --enable-tests \
  28     --dynlibdir=/usr/lib --libsubdir=\$compiler/site-local/\$pkgid --ghc-option=-fllvm \
  29     --ghc-option=-optl-Wl\,-z\,relro\,-z\,now \
  30     --ghc-option='-pie'
  31
  32   runhaskell Setup build $MAKEFLAGS
  33   runhaskell Setup register --gen-script
  34   runhaskell Setup unregister --gen-script
  35   sed -i -r -e "s|ghc-pkg.*update[^ ]* |&'--force' |" register.sh
  36   sed -i -r -e "s|ghc-pkg.*unregister[^ ]* |&'--force' |" unregister.sh
  37 }
  38
  39 check() {
  40   cd $_hkgname-$pkgver
  41   runhaskell Setup test --show-details=direct
  42 }
  43
  44 package() {
  45   cd $_hkgname-$pkgver
  46
  47   install -D -m744 register.sh "$pkgdir"/usr/share/haskell/register/$pkgname.sh
  48   install -D -m744 unregister.sh "$pkgdir"/usr/share/haskell/unregister/$pkgname.sh
  49   runhaskell Setup copy --destdir="$pkgdir"
  50   install -D -m644 LICENSE -t "$pkgdir"/usr/share/licenses/$pkgname/
  51   rm -f "$pkgdir"/usr/share/doc/$pkgname/LICENSE
  52 }