hopenpgp-tools/repos/community-x86_64/PKGBUILD

   1 # Maintainer: Felix Yan <felixonmars@archlinux.org>
   2 # Contributor: Arch Haskell Team <arch-haskell@haskell.org>
   3
   4 pkgname=hopenpgp-tools
   5 pkgver=0.23.7
   6 pkgrel=112
   7 pkgdesc="hOpenPGP-based command-line tools"
   8 url="https://salsa.debian.org/clint/hopenpgp-tools"
   9 license=("AGPL3")
  10 arch=('x86_64')
  11 depends=('ghc-libs' 'haskell-aeson' 'haskell-base16-bytestring' 'haskell-binary-conduit'
  12          'haskell-conduit' 'haskell-conduit-extra' 'haskell-cryptonite' 'haskell-errors'
  13          'haskell-fgl' 'haskell-graphviz' 'haskell-hopenpgp' 'haskell-http-client'
  14          'haskell-http-client-tls' 'haskell-http-types' 'haskell-ixset-typed' 'haskell-lens'
  15          'haskell-memory' 'haskell-monad-loops' 'haskell-openpgp-asciiarmor'
  16          'haskell-optparse-applicative' 'haskell-prettyprinter'
  17          'haskell-prettyprinter-ansi-terminal' 'haskell-prettyprinter-convert-ansi-wl-pprint'
  18          'haskell-resourcet' 'haskell-time-locale-compat' 'haskell-unordered-containers'
  19          'haskell-vector' 'haskell-yaml')
  20 makedepends=('alex' 'happy' 'ghc')
  21 source=(https://hackage.haskell.org/packages/archive/${pkgname}/${pkgver}/${pkgname}-${pkgver}.tar.gz)
  22 sha512sums=('6710829a097050615a981a903537e08bff5aee7b1e6f3222cf033d953ba08193da3cd7bd2c4aad2afabd9831fe6313135d3efb95742a15826a59a46f77601a0d')
  23
  24 build() {
  25     cd "${srcdir}/${pkgname}-${pkgver}"
  26
  27     runhaskell Setup configure -O --prefix=/usr --enable-executable-dynamic --docdir=/usr/share/doc/$pkgname --datasubdir=$pkgname
  28     runhaskell Setup build $MAKEFLAGS
  29 }
  30
  31 package() {
  32     cd "${srcdir}/${pkgname}-${pkgver}"
  33     runhaskell Setup copy --destdir="${pkgdir}"
  34
  35     rm "$pkgdir/usr/share/doc/hopenpgp-tools/LICENSE"
  36     rmdir "$pkgdir/usr/share/doc/hopenpgp-tools" "$pkgdir/usr/share/doc" "$pkgdir/usr/share"
  37 }