hugin/repos/community-x86_64/PKGBUILD

   1 # Maintainer: Bruno Pagani <archange@archlinux.org>
   2 # Maintainer: Caleb Maclennan <caleb@alerque.com>
   3 # Contributor: Gaetan Bisson <bisson@archlinux.org>
   4 # Contributor: Tobias Kieslich <tobias@archlinux.org>
   5 # Contributor: Giovanni Scafora <giovanni@archlinux.org>
   6 # Contributor: Dominik Ryba <domryba@post.pl>
   7
   8 pkgname=hugin
   9 pkgver=2022.0.0
  10 pkgrel=6
  11 pkgdesc="Panorama photo stitcher"
  12 arch=(x86_64)
  13 url="http://hugin.sourceforge.net/"
  14 license=(GPL)
  15 depends=(wxwidgets-gtk3 boost-libs libtiff libpano13 libjpeg libpng openexr vigra
  16          exiv2 glew sqlite lcms2 lapack fftw glu libxi libxmu python
  17          lensfun enblend-enfuse)
  18 makedepends=(cmake boost tclap mesa swig)
  19 optdepends=('perl-image-exiftool: GPano tags support'
  20             'dcraw: RAW import using dcraw'
  21             'darktable: RAW import using darktable'
  22             'rawtherapee: RAW import using rawtherapee')
  23 source=(https://downloads.sourceforge.net/${pkgname}/${pkgname}-${pkgver}.tar.bz2)
  24 sha256sums=('97c8562a0ba9a743e0b955a43dfde048b1c60cd9e5f2ee2b69de1a81646e05a7')
  25
  26 build() {
  27   cmake -B build -S ${pkgname}-${pkgver} \
  28     -DCMAKE_INSTALL_PREFIX=/usr \
  29     -DENABLE_LAPACK=yes \
  30     -DBUILD_HSI=ON \
  31     -DUSE_GDKBACKEND_X11=ON
  32   make -C build
  33 }
  34
  35 package() {
  36   make -C build DESTDIR="${pkgdir}" install
  37 }