ibus-chewing/trunk/PKGBUILD

   1 # Maintainer: Felix Yan <felixonmars@archlinux.org>
   2 # Maintainer: Chih-Hsuan Yen <yan12125@archlinux.org>
   3 # Contributor: Thomas Dziedzic < gostrc at gmail >
   4 # Contributor: Rainy <rainylau(at)gmail(dot)com>
   5 # Contributor: Lee.MaRS <leemars@gmail.com>
   6 # Contributor: Hiroshi Yui <hiroshiyui@gmail.com>
   7
   8 pkgname=ibus-chewing
   9 pkgver=1.6.1+12+gc1e7f0d
  10 _commit=c1e7f0d97aa8bb1a1166621c3f0780daa0db06c1
  11 pkgrel=4
  12 pkgdesc='Chinese Chewing Engine for IBus Framework'
  13 arch=('x86_64')
  14 license=('GPL')
  15 url='https://github.com/definite/ibus-chewing'
  16 depends=('ibus' 'libchewing' 'libxtst' 'gtk3')
  17 makedepends=('gob2' 'cmake-fedora' 'git')
  18 source=("git+https://github.com/definite/ibus-chewing.git#commit=$_commit")
  19 sha512sums=('SKIP')
  20
  21 pkgver() {
  22   cd $pkgname
  23   git describe --always | sed 's/-/+/g'
  24 }
  25
  26 prepare() {
  27   cd $pkgname
  28
  29   # Revert an incomplete feature, see https://github.com/definite/ibus-chewing/issues/154
  30   git revert -n 70a1935290c9e8bcb8e098b91711f97269619c6f
  31 }
  32
  33 build() {
  34   cd $pkgname
  35
  36   cmake -B build -S . \
  37     -DCMAKE_INSTALL_PREFIX=/usr \
  38     -DCMAKE_BUILD_TYPE=None \
  39     -DLIBEXEC_DIR=/usr/lib/ibus
  40
  41   # XXX: updated *.po files contain no translated strings. Maybe because fedora.zanata.org is down
  42   # https://github.com/definite/ibus-chewing/issues/150
  43   touch build/po/ibus-chewing.pot
  44   cp -v po/*.po build/po/
  45
  46   make -C build -j1
  47 }
  48
  49 package() {
  50   cd $pkgname/build
  51   make DESTDIR="$pkgdir" install
  52 }