jack_capture/trunk/PKGBUILD

   1 # Maintainer: David Runge <dave@sleepmap.de>
   2 # Contributor: Christopher Arndt <aur -at- chrisarndt -dot- de>
   3 # Contributor: speps <speps at aur dot archlinux dot org>
   4 # Contributor: hm_b <holger@music-nerds.net>
   5 # Contributor: Leslie P. Polzer <polzer@stardawn.org>
   6 # Contributor: Philipp Überbacher <murks at lavabit dot com>
   7
   8 pkgname=jack_capture
   9 pkgver=0.9.73
  10 pkgrel=8
  11 pkgdesc="Simple command line tool to record JACK audio output to a file"
  12 arch=('x86_64')
  13 url="https://github.com/kmatheussen/jack_capture"
  14 license=('GPL2')
  15 groups=('pro-audio')
  16 depends=('jack' 'lame' 'liblo')
  17 optdepends=('zenity: gtk2 GUI')
  18 source=("${pkgname}-${pkgver}.tar.gz::https://github.com/kmatheussen/${pkgname}/archive/${pkgver}.tar.gz")
  19 sha512sums=('eecab2e26d5e83b65adf386d6fb38f2d9169cf1574e462ec455367f7d98f4f4d5a9d0766b9c572cfdcb43c55ae914bb8a2222267842c9912e2afe13c1f7b0038')
  20
  21 build() {
  22   cd "${pkgname}-${pkgver}"
  23   make
  24 }
  25
  26 package(){
  27   cd "${pkgname}-${pkgver}"
  28   make PREFIX='/usr' DESTDIR="${pkgdir}" install
  29   # gtk2 gui
  30   install -vDm 755 "${pkgname}_gui" "${pkgdir}/usr/bin/${pkgname}_gui"
  31   # doc
  32   install -vDm 644 README -t "${pkgdir}/usr/share/doc/${pkgname}/"
  33 }
  34 # vim:set ts=2 sw=2 et: