jless/trunk/PKGBUILD

   1 # Maintainer: George Rawlinson <grawlinson@archlinux.org>
   2 # Maintainer: Orhun Parmaksız <orhun@archlinux.org>
   3 # Contributor: João Vitor S. Anjos <jvanjos at protonmail dot com>
   4
   5 pkgname=jless
   6 pkgver=0.8.0
   7 pkgrel=1
   8 pkgdesc='A command-line pager for JSON data'
   9 arch=('x86_64')
  10 url="https://github.com/PaulJuliusMartinez/jless"
  11 license=('MIT')
  12 depends=('gcc-libs' 'libxcb' 'libxkbcommon')
  13 makedepends=('git' 'rust' 'python')
  14 options=('!lto')
  15 _commit='6f3b7bbe8ca463467a389ffe3c473993e4c4acd8'
  16 source=("$pkgname::git+$url.git#commit=$_commit")
  17 b2sums=('SKIP')
  18
  19 pkgver() {
  20   cd "$pkgname"
  21
  22   git describe --tags | sed 's/^v//'
  23 }
  24
  25 prepare() {
  26   cd "$pkgname"
  27
  28   cargo fetch --locked --target "$CARCH-unknown-linux-gnu"
  29 }
  30
  31 build() {
  32   cd "$pkgname"
  33
  34   cargo build --release --frozen
  35 }
  36
  37 check() {
  38   cd "$pkgname"
  39
  40   cargo test --frozen
  41 }
  42
  43 package() {
  44   cd "$pkgname"
  45
  46   # binary
  47   install -vDm755 -t "$pkgdir/usr/bin" target/release/jless
  48
  49   # documentation
  50   install -vDm644 -t "$pkgdir/usr/share/doc/$pkgname" README.md
  51
  52   # license
  53   install -vDm644 -t "$pkgdir/usr/share/licenses/$pkgname" LICENSE
  54 }
  55
  56 # vim:set ts=2 sw=2 et: