kcm-fcitx/trunk/PKGBUILD

   1 # Maintainer: Felix Yan <felixonmars@archlinux.org>
   2 # Contributor: poplarch <poplarch@gmail.com>
   3
   4 pkgname=kcm-fcitx
   5 pkgver=0.5.6
   6 pkgrel=1
   7 pkgdesc="KDE Config Module for Fcitx"
   8 arch=('x86_64')
   9 url="https://github.com/fcitx/kcm-fcitx"
  10 license=('GPL')
  11 depends=('fcitx-qt5' 'knewstuff' 'kcmutils')
  12 makedepends=('extra-cmake-modules')
  13 source=("https://download.fcitx-im.org/$pkgname/$pkgname-${pkgver}.tar.xz"{,.sig})
  14 sha512sums=('a3d378ecd9ea9fa5bcc42c75e5b0b0ac2ba6c94fda93b7213d821546bb83b5904c75c2fc9482cd7b47fbf5ad81a0641b7ec345aa2e630c8795bf8d5b89f9cd3b'
  15             'SKIP')
  16 validpgpkeys=('2CC8A0609AD2A479C65B6D5C8E8B898CBF2412F9') # Weng Xuetian <wengxt@gmail.com>
  17
  18 prepare() {
  19   mkdir build
  20 }
  21
  22 build() {
  23   cd build
  24
  25   cmake ../$pkgname-$pkgver \
  26     -DCMAKE_INSTALL_PREFIX=/usr \
  27     -DCMAKE_BUILD_TYPE=Release \
  28     -DCMAKE_INSTALL_LIBDIR=lib \
  29     -DKDE_INSTALL_USE_QT_SYS_PATHS=ON
  30   make
  31 }
  32
  33 package() {
  34   cd build
  35   make DESTDIR="$pkgdir" install
  36 }