kvazaar/trunk/PKGBUILD

   1 # Maintainer: Daniel Bermond <dbermond@archlinux.org>
   2
   3 pkgname=kvazaar
   4 pkgver=2.2.0
   5 pkgrel=1
   6 pkgdesc='An open-source HEVC encoder'
   7 arch=('x86_64')
   8 url='https://github.com/ultravideo/kvazaar/'
   9 license=('BSD')
  10 depends=('crypto++')
  11 makedepends=('git' 'yasm')
  12 checkdepends=('ffmpeg' 'hm')
  13 source=("git+https://github.com/ultravideo/kvazaar.git#tag=v${pkgver}"
  14         'git+https://github.com/ultravideo/greatest.git')
  15 sha256sums=('SKIP'
  16             'SKIP')
  17
  18 prepare() {
  19     git -C kvazaar submodule init
  20     git -C kvazaar config --local submodule.greatest.url "${srcdir}/greatest"
  21     git -C kvazaar -c protocol.file.allow='always' submodule update
  22     autoreconf -fi kvazaar
  23 }
  24
  25 build() {
  26     cd kvazaar
  27     ./configure --prefix='/usr' --with-cryptopp
  28     make
  29 }
  30
  31 check() {
  32     make -C kvazaar check
  33 }
  34
  35 package() {
  36     make -C kvazaar DESTDIR="$pkgdir" install
  37     install -d -m755 "${pkgdir}/usr/share/licenses/kvazaar"
  38     mv "${pkgdir}/usr/share/doc/kvazaar"/LICENSE* "${pkgdir}/usr/share/licenses/${pkgname}"
  39 }