lastpass-cli/trunk/PKGBUILD

   1 # Maintainer: Massimiliano Torromeo <massimiliano.torromeo@gmail.com>
   2 # Contributor: Oliver Lantwin <olantwin+aur@gmail.com>
   3 # Contributor: Gabriel Peixoto <gabrielrcp@gmail.com>
   4
   5 pkgname=lastpass-cli
   6 pkgver=1.3.4
   7 pkgrel=1
   8 pkgdesc="LastPass command line interface tool"
   9 arch=('x86_64')
  10 url="https://lastpass.com/"
  11 license=('GPL2')
  12 depends=('openssl' 'curl' 'libxml2')
  13 makedepends=('asciidoc' 'cmake' 'bash-completion')
  14 optdepends=('xclip: clipboard support'
  15             'pinentry: securely read passwords')
  16 source=("https://github.com/lastpass/lastpass-cli/archive/v$pkgver/$pkgname-$pkgver.tar.gz")
  17 sha256sums=('f747e42dac3441131f9ebf0c119f27c57e8701968de7718224c2cdeb91300b6b')
  18
  19 build() {
  20   cd "$srcdir"/$pkgname-$pkgver
  21   CFLAGS+=' -fcommon' # https://wiki.gentoo.org/wiki/Gcc_10_porting_notes/fno_common
  22   cmake . -DCMAKE_INSTALL_PREFIX="/usr"
  23   make
  24 }
  25
  26 package() {
  27   cd "$srcdir"/$pkgname-$pkgver
  28   make DESTDIR="$pkgdir" install install-doc
  29   install -Dm0644 contrib/lpass_zsh_completion "$pkgdir"/usr/share/zsh/site-functions/_lpass
  30   install -Dm0644 contrib/completions-lpass.fish "$pkgdir"/usr/share/fish/vendor_completions.d/lpass.fish
  31 }
  32
  33 # vim:set ts=2 sw=2 et: