lib32-libice/trunk/PKGBUILD

   1 # Contributor: Alexander Baldeck <alexander@archlinux.org>
   2 # Maintainer: Jan de Groot <jgc@archlinux.org>
   3
   4 _pkgbasename=libice
   5 pkgname=lib32-$_pkgbasename
   6 pkgver=1.1.1
   7 pkgrel=1
   8 pkgdesc="X11 Inter-Client Exchange library (32-bit)"
   9 arch=(x86_64)
  10 url="https://xorg.freedesktop.org/"
  11 depends=('lib32-glibc' $_pkgbasename)
  12 makedepends=('xtrans>=1.2.5' 'xorg-util-macros' 'xorgproto')
  13 source=(${url}/releases/individual/lib/libICE-${pkgver}.tar.xz{,.sig})
  14 license=('custom')
  15 sha1sums=('7e4b51bb5633d7fc7d1f4e161d231591ab545f0b'
  16           'SKIP')
  17 sha256sums=('03e77afaf72942c7ac02ccebb19034e6e20f456dcf8dddadfeb572aa5ad3e451'
  18             'SKIP')
  19 validpgpkeys=('3BB639E56F861FA2E86505690FDD682D974CA72A') # Matt Turner <mattst88@gmail.com>
  20
  21 build() {
  22   cd "${srcdir}/libICE-${pkgver}"
  23
  24   export CC="gcc -m32"
  25   export PKG_CONFIG_PATH="/usr/lib32/pkgconfig"
  26
  27   ./configure --prefix=/usr --sysconfdir=/etc --libdir=/usr/lib32
  28
  29   make
  30 }
  31
  32 package() {
  33   cd "${srcdir}/libICE-${pkgver}"
  34   make DESTDIR="${pkgdir}" install
  35
  36   rm -rf "${pkgdir}"/usr/{include,share}
  37
  38   mkdir -p "$pkgdir/usr/share/licenses"
  39   ln -s $_pkgbasename "$pkgdir/usr/share/licenses/$pkgname"
  40 }