lib32-libidn11/trunk/PKGBUILD

   1 # Maintainer: Maxime Gauduin <alucryd@archlinux.org>
   2 # Contributor: Ronald van Haren <ronald.archlinux.org>
   3 # Contributor: Jan de Groot <jgc.archlinux.org>
   4 # Contributor: Eric Johnson <eric.archlinux.org>
   5
   6 pkgname=lib32-libidn11
   7 pkgver=1.33
   8 pkgrel=2
   9 pkgdesc='Implementation of the Stringprep, Punycode and IDNA specifications'
  10 url='https://www.gnu.org/software/libidn/'
  11 arch=('x86_64')
  12 license=('GPL3' 'LGPL')
  13 depends=('lib32-glibc')
  14 makedepends=('git' 'gperf' 'gtk-doc')
  15 source=("git+https://git.savannah.gnu.org/git/libidn.git?signed#tag=libidn-${pkgver//./-}"
  16         'libidn11-subdirs.patch')
  17 validpgpkeys=('9AA9BDB11BB1B99A21285A330664A76954265E8C') # Simon Josefsson <simon@josefsson.org>
  18 sha256sums=('SKIP'
  19             '0c440fe12da1372e8f9388e6b2bed3f0dd57d2696e08cb8d92e9880fd315ca63')
  20
  21 prepare() {
  22   cd libidn
  23
  24   patch -Np1 -i ../libidn11-subdirs.patch
  25   make -f GNUmakefile autoreconf
  26 }
  27
  28 build() {
  29   cd libidn
  30
  31   export CC='gcc -m32'
  32   export PKG_CONFIG_PATH='/usr/lib32/pkgconfig'
  33
  34   ./configure \
  35     --prefix='/usr' \
  36     --libdir='/usr/lib32' \
  37     --disable-nls \
  38     --disable-static
  39   make
  40 }
  41
  42 package() {
  43   make DESTDIR="${pkgdir}" -C libidn install
  44   rm -rf "${pkgdir}"/usr/{include,lib32/{libidn.so,pkgconfig}}
  45 }
  46
  47 # vim: ts=2 sw=2 et: