lib32-libnghttp2/trunk/PKGBUILD

   1 # Maintainer: Anatol Pomozov
   2 # Contributor: Zhuoyun Wei <wzyboy@wzyboy.org>
   3
   4 pkgname=lib32-libnghttp2
   5 _tag='00d2715ced9ea24e90a3bcbef1a54d5cecf208c5' # git rev-parse v${pkgver}
   6 pkgver=1.53.0
   7 pkgrel=1
   8 pkgdesc='Framing layer of HTTP/2 is implemented as a reusable C library (32-bit)'
   9 arch=('x86_64')
  10 url='https://nghttp2.org/'
  11 license=('MIT')
  12 depends=('lib32-glibc' 'libnghttp2')
  13 makedepends=('git')
  14 validpgpkeys=('F4F3B91474D1EB29889BD0EF7E8403D5D673C366') # Tatsuhiro Tsujikawa <tatsuhiro.t@gmail.com>
  15 source=("git+https://github.com/nghttp2/nghttp2.git#tag=${_tag}?signed")
  16 sha512sums=('SKIP')
  17
  18 prepare() {
  19   cd nghttp2
  20
  21   autoreconf -i
  22 }
  23
  24 build() {
  25   cd nghttp2
  26   export CC='gcc -m32'
  27   export CXX='g++ -m32'
  28   export PKG_CONFIG_PATH='/usr/lib32/pkgconfig'
  29
  30   ./configure \
  31     --prefix=/usr \
  32     --disable-examples \
  33     --disable-python-bindings \
  34     --enable-lib-only \
  35     --libdir=/usr/lib32
  36   make
  37 }
  38
  39 check() {
  40   cd nghttp2
  41   make check
  42 }
  43
  44 package() {
  45   cd nghttp2/lib
  46
  47   make DESTDIR="$pkgdir" install
  48   rm -r "$pkgdir"/usr/include
  49   install -Dm644 ../COPYING -t "$pkgdir"/usr/share/licenses/$pkgname
  50 }