lib32-sdl2_mixer/repos/multilib-x86_64/PKGBUILD

   1 # Maintainer: Maxime Gauduin <alucryd@archlinux.org>
   2 # Contributor: carstene1ns <arch.carsten@teibes.de>
   3 # Contributor: Jameson Pugh <imntreal@gmail.com>
   4 # Contributor: Sven-Hendrik Haase <sh@lutzhaase.com>
   5
   6 pkgname=lib32-sdl2_mixer
   7 pkgver=2.6.3
   8 pkgrel=1
   9 pkgdesc='A simple multi-channel audio mixer'
  10 arch=(x86_64)
  11 url=https://github.com/libsdl-org/SDL_mixer
  12 license=(MIT)
  13 depends=(
  14   lib32-flac
  15   lib32-glibc
  16   lib32-libmodplug
  17   lib32-libvorbis
  18   lib32-mpg123
  19   lib32-sdl2
  20   sdl2_mixer
  21 )
  22 makedepends=(
  23   git
  24   lib32-fluidsynth
  25 )
  26 optdepends=('lib32-fluidsynth: MIDI software synth, replaces built-in timidity')
  27 _tag=6103316427a8479e5027e41ab9948bebfc1c3c19
  28 source=(git+https://github.com/libsdl-org/SDL_mixer.git#tag=${_tag})
  29 b2sums=('SKIP')
  30
  31 prepare() {
  32   cd SDL_mixer
  33   ./autogen.sh
  34 }
  35
  36 pkgver() {
  37   cd SDL_mixer
  38   git describe --tags | sed 's/^release-//'
  39 }
  40
  41 build() {
  42   cd SDL_mixer
  43   export CC='gcc -m32'
  44   export CXX='g++ -m32'
  45   export PKG_CONFIG_PATH=/usr/lib32/pkgconfig
  46   ./configure \
  47     --prefix=/usr \
  48     --libdir=/usr/lib32 \
  49     --disable-static
  50   make
  51 }
  52
  53 package() {
  54   make DESTDIR="${pkgdir}" -C SDL_mixer install
  55   rm -rf "${pkgdir}"/usr/include
  56   install -dm 755 "${pkgdir}"/usr/share/licenses
  57   ln -s sdl2_mixer "${pkgdir}"/usr/share/licenses/lib32-sdl2_mixer
  58 }
  59
  60 # vim: ts=2 sw=2 et: