liboggz/repos/community-x86_64/PKGBUILD

   1 # Maintainer: David Runge <dave@sleepmap.de>
   2 # Contributor: Giovanni Scafora <giovanni@archlinux.org>
   3 # Contributor: Vincent Cappe <vcappe at gmail dot com>
   4 # Contributor: Jeff Bailes <thepizzaking at gmail dot com>
   5 # Contributor: SpepS <dreamspepser at yahoo dot it>
   6
   7 pkgname=liboggz
   8 pkgver=1.1.1
   9 pkgrel=7
  10 pkgdesc="A simple programming interface for reading and writing Ogg files and streams"
  11 arch=('x86_64')
  12 url="https://www.xiph.org/oggz/"
  13 license=('BSD')
  14 depends=('bash' 'libogg')
  15 makedepends=('doxygen')
  16 provides=('liboggz.so')
  17 source=("https://downloads.xiph.org/releases/${pkgname}/${pkgname}-${pkgver}.tar.gz")
  18 sha512sums=('8f5fc8ca49cb6f7a1160a9c1932876b771d55985d59ddc1f48497dfc08641414a58244d7a7e52bfcecdb69f52913d0123efd8f92513f8b9064e4abe1442f2cba')
  19
  20 build() {
  21   cd "${pkgname}-${pkgver}"
  22   ./configure --prefix=/usr \
  23               --enable-static=no
  24   make
  25 }
  26
  27 package() {
  28   cd "${pkgname}-${pkgver}"
  29   make DESTDIR="${pkgdir}" install
  30   # license
  31   install -vDm 644 COPYING -t "${pkgdir}/usr/share/licenses/${pkgname}"
  32   # bash completion
  33   install -vDm 644 bash-completion/oggz \
  34     -t "${pkgdir}/usr/share/bash-completion/completions/"
  35   # docs
  36   install -vDm 644 {AUTHORS,ChangeLog,NEWS,README,TODO} \
  37     -t "${pkgdir}/usr/share/doc/${pkgname}"
  38 }