libva1/trunk/PKGBUILD

   1 # Maintainer: Maxime Gauduin <alucryd@archlonux.org>
   2 # Contributor: Bartłomiej Piotrowski <bpiotrowski@archlinux.org>
   3 # Contributor: Ionut Biru <ibiru@archlinux.org>
   4
   5 pkgname=libva1
   6 pkgver=1.8.3
   7 pkgrel=3
   8 pkgdesc='Video Acceleration (VA) API for Linux'
   9 arch=('x86_64')
  10 url='https://01.org/linuxmedia/vaapi'
  11 license=('MIT')
  12 depends=('libdrm' 'libgl' 'libx11' 'libxext' 'libxfixes' 'wayland')
  13 makedepends=('git' 'libglvnd' 'mesa')
  14 provides=(
  15   'libva-drm.so' 'libva-glx.so' 'libva-wayland.so' 'libva-x11.so' 'libva.so'
  16 )
  17 source=("git+https://github.com/intel/libva.git#tag=${pkgver}"
  18         '50-libva1.conf')
  19 sha256sums=('SKIP'
  20             '0b492e511aec4319b7da6d5e02a85d4d092ed13fd5d2b01832452ebf21c1aac7')
  21
  22 prepare() {
  23   cd libva
  24
  25   NOCONFIGURE=1 ./autogen.sh
  26 }
  27
  28 build() {
  29   cd libva
  30
  31   ./configure \
  32     --prefix='/usr' \
  33     --includedir='/usr/include/libva1' \
  34     --libdir='/usr/lib/libva1' \
  35     --with-drivers-path='/usr/lib/libva1/dri' \
  36     --disable-va-messaging
  37   make
  38 }
  39
  40 package() {
  41   make DESTDIR="${pkgdir}" -C libva install
  42   install -Dm 644 libva/COPYING -t "${pkgdir}"/usr/share/licenses/libva1
  43   install -Dm 644 50-libva1.conf -t "${pkgdir}"/etc/ld.so.conf.d/
  44 }
  45
  46 # vim: ts=2 sw=2 et: