light/trunk/PKGBUILD

   1 # Maintainer: Maxim Baz <$pkgname at maximbaz dot com>
   2 # Contributor: Fredrik Haikarainen <fredrik.haikarainen@gmail.com>
   3 # Contributor: Marcin (CTRL) Wieczorek <marcin@marcin.co>
   4
   5 pkgname=light
   6 pkgver=1.2.2
   7 pkgrel=3
   8 pkgdesc='Program to easily change brightness on backlight-controllers.'
   9 arch=('x86_64')
  10 url='https://github.com/haikarainen/light'
  11 license=('GPL3')
  12 depends=('glibc')
  13 install="${pkgname}.install"
  14 source=("${pkgname}-${pkgver}.tar.gz::https://github.com/haikarainen/light/archive/v${pkgver}.tar.gz"
  15         "114.patch"
  16         "122.patch")
  17 sha256sums=('62e889ee9be80fe808a972ef4981acc39e83a20f9a84a66a82cd1f623c868d9c'
  18             'e0bee2249f59f66cb02ef98dc18e36172d141eb8b9f1bb1c2c8de8323c9ad73e'
  19             '7dd149ef9ce9647f70a8047c0690e4ff121670ba58cf5aaac2fd8cd29e03d03f')
  20
  21 prepare() {
  22     cd "${pkgname}-${pkgver}"
  23     patch -Np1 -i "${srcdir}/114.patch"
  24     patch -Np1 -i "${srcdir}/122.patch"
  25 }
  26
  27 build() {
  28     cd "${pkgname}-${pkgver}"
  29     ./autogen.sh
  30     ./configure --prefix=/usr --with-udev
  31     make
  32 }
  33
  34 package() {
  35     cd "${pkgname}-${pkgver}"
  36     make DESTDIR="${pkgdir}" PREFIX=/usr install
  37 }
  38
  39 # vim:set ts=4 sw=4 et: