linuxconsole/repos/community-x86_64/PKGBUILD

   1 # Maintainer: Sergej Pupykin <pupykin.s+arch@gmail.com>
   2 # Maintainer:  Andrzej Giniewicz <gginiu@gmail.com>
   3
   4 pkgname=linuxconsole
   5 pkgver=1.8.1
   6 pkgrel=1
   7 pkgdesc="Set of utilities for joysticks and serial devices"
   8 arch=('x86_64')
   9 url="https://sourceforge.net/projects/linuxconsole/"
  10 license=('GPL')
  11 makedepends=('sdl2')
  12 provides=('joystick' 'inputattach')
  13 replaces=('joystick' 'inputattach')
  14 optdepends=('sdl2: for ffmvforce utility')
  15 backup=('etc/conf.d/inputattach')
  16 validpgpkeys=('79D9C58C50D6B5AA65D530C1759778A9A36B494F')
  17 source=(https://prdownloads.sourceforge.net/linuxconsole/linuxconsoletools-$pkgver.tar.bz2{,.sig}
  18         'inputattach.conf.d'
  19         'inputattach.service'
  20         'inputattachctl')
  21 sha256sums=('4da29745c782b7db18f5f37c49e77bf163121dd3761e2fc7636fa0cbf35c2456'
  22             'SKIP'
  23             '3807b2b34bea40c6d6036629ac3eaee31b44549c81fac62e922eb6524f0b203e'
  24             '3fe8df1d4330ad95a02206946440576ad3a56230d43107f1d703bff077182f84'
  25             '908e3a6cec41bd4fbe7066fb54213a80c96d91b219ca045399a54e65c0995c8c')
  26
  27 prepare() {
  28   cd "${srcdir}"/linuxconsoletools-$pkgver
  29   sed -i 's|lib/udev|usr/lib/udev|g' utils/Makefile
  30 }
  31
  32 build() {
  33   cd "${srcdir}"/linuxconsoletools-$pkgver
  34   make PREFIX=/usr
  35 }
  36
  37 package() {
  38   cd "${srcdir}"/linuxconsoletools-$pkgver
  39   make PREFIX=/usr DESTDIR="${pkgdir}" install
  40
  41   install -Dm755 "$srcdir"/inputattachctl "$pkgdir"/usr/bin/inputattachctl
  42   install -Dm644 "$srcdir"/inputattach.conf.d "$pkgdir/etc/conf.d/inputattach"
  43   install -Dm644 "$srcdir"/inputattach.service "$pkgdir"/usr/lib/systemd/system/inputattach.service
  44 }