llpp/trunk/PKGBUILD

   1 # Maintainer: Daniel M. Capella <polyzen@archlinux.org>
   2 # Contributor: Eli Schwartz <eschwartz@archlinux.org>
   3 # Contributor: earnestly
   4
   5 pkgname=llpp
   6 pkgver=34
   7 pkgrel=1
   8 pkgdesc='opengl accelerated pdf viewer based on mupdf'
   9 arch=('x86_64')
  10 url=https://github.com/moosotc/llpp
  11 license=('GPL3')
  12 depends=('freetype2' 'gumbo-parser' 'jbig2dec' 'libgl' 'libjpeg' 'openjpeg2')
  13 makedepends=('asciidoc' 'git' 'libmupdf' 'ocaml' 'ocaml-lablgl')
  14 optdepends=('djvulibre: for llppac djvu conversion'
  15             'ghostscript: for llppac ps, dvi, and djvu conversion'
  16             'imagemagick: for llppac image conversion'
  17             'inotify-tools: for the llpp.inotify autoreload wrapper'
  18             'librsvg: for llppac svg conversion'
  19             'unoconv: for llppac office conversion')
  20 options=('!strip')
  21 source=("git+$url#tag=v$pkgver"
  22         'system-makedeps.patch')
  23 b2sums=('SKIP'
  24         '3701e6163b8c584c2fc71352273769357cc289b9d298325bfd6cb86dd87196fcb53f416691074ef5e9279f084d24b93f2091bd49bb36a4a1be30c2846526b107')
  25
  26 prepare() {
  27   cd $pkgname
  28   patch --forward --strip=1 --input=../system-makedeps.patch
  29
  30   # Restore desktop file
  31   git revert --no-commit aad4b1e65e581ff7a096a3c3901b222a9c127a1c
  32 }
  33
  34 build() {
  35   cd $pkgname
  36   bash ./build.bash build
  37   bash ./build.bash build doc
  38 }
  39
  40 package() {
  41   cd $pkgname
  42   install -Dt "$pkgdir"/usr/bin build/llpp misc/llpp{.inotify,ac}
  43   install -Dm644 -t "$pkgdir"/usr/share/applications misc/llpp.desktop
  44   install -Dm644 -t "$pkgdir"/usr/share/man/man1 build/doc/*.1
  45 }