luminancehdr/trunk/PKGBUILD

   1 # Maintainer: Jaroslav Lichtblau <svetlemodry@archlinux.org>
   2 # Contributor: Lukas Jirkovsky <l.jirkovsky@gmail.com>
   3 # Contributor: Dmitry N. Shilov <stormblast@land.ru>
   4
   5 pkgname=luminancehdr
   6 pkgver=2.6.1
   7 pkgrel=14
   8 pkgdesc='Open source graphical user interface application that aims to provide a workflow for HDR imaging'
   9 arch=('x86_64')
  10 url='http://qtpfsgui.sourceforge.net/'
  11 license=('GPL')
  12 depends=('exiv2' 'fftw' 'gsl' 'lcms2' 'libraw' 'openexr' 'qt5-webengine' 'qt5-svg'
  13          'ccfits' 'desktop-file-utils' 'hicolor-icon-theme' 'boost-libs')
  14 makedepends=('cmake' 'boost' 'gtest' 'qt5-tools' 'eigen')
  15 optdepends=('hugin: align image stack functionality')
  16 changelog=$pkgname.changelog
  17 options=('!emptydirs')
  18 source=(https://sourceforge.net/projects/qtpfsgui/files/luminance/$pkgver/luminance-hdr-$pkgver.tar.bz2
  19         luminancehdr-openexr3.patch
  20         fix-headers.patch)
  21 sha512sums=('d909194ff13df1d3a9ad5c08a0fad5b28831c1ff5317ec9240af16b21cc87dff162c9e2433c5ec1103e4a3a5001de14a9a1dd3d75b3cb24433c93694810c24f7'
  22             '78da713154042f125511ddc7ad184f961c92fa679ff0aa5d33700b619a0eed973722ea9f51c44c58595043ea308f4f3c44f6613b88fbb41e5159849bc0f8741e'
  23             '6d7ae3df647ffb67a27ef2729c8e8fd04e2b400bd960744dd0172406bc27773156a2b0bd67a7b71157cc59d0f528fbe00882085baa42f503dd506baa2826d0e9')
  24
  25 prepare() {
  26   patch -d luminance-hdr-$pkgver -p1 < luminancehdr-openexr3.patch
  27   patch -d luminance-hdr-$pkgver -p1 < fix-headers.patch
  28 }
  29
  30 build() {
  31   cd "${srcdir}"/luminance-hdr-$pkgver
  32
  33   cmake -DCMAKE_INSTALL_PREFIX=/usr -DCMAKE_BUILD_TYPE=Release
  34   make
  35 }
  36
  37 package() {
  38   cd "${srcdir}"/luminance-hdr-$pkgver
  39
  40   make DESTDIR="${pkgdir}" install
  41 }