lurk/trunk/PKGBUILD

   1 # Maintainer: Orhun Parmaksız <orhun@archlinux.org>
   2 # Contributor: Kyle Manna <kyle [at] kylemanna [dot] com>
   3
   4 pkgname=lurk
   5 pkgver=0.3.3
   6 pkgrel=1
   7 pkgdesc="A pretty (simple) alternative to strace"
   8 arch=('x86_64')
   9 url="https://github.com/JakWai01/lurk"
  10 license=('MIT' 'Apache')
  11 depends=('gcc-libs')
  12 makedepends=('cargo')
  13 source=("$pkgname-$pkgver.tar.gz::$url/archive/v$pkgver.tar.gz"
  14         "$pkgname-$pkgver-fix-tests.patch::$url/commit/87eb4aa8bf9a551b24cec2146699cb2c22d62019.patch")
  15 sha512sums=('0f19b2a529e65e5f25c84cc30380dc3c83e56faf58e469a669ae8e904b6b0abd9507132ebbce4d3841870a8bdb3225dd402681848b46a3411a2b0065663d6d60'
  16             '48861e66cfa466def8543b4edc8bb6e1b6e5ace5ae430129ca0602c231f2772fd4a8a6f041f31c5f60ea9ceac6ff731b22d3f6179c932f6a1f9c7e6ac34f8db7')
  17
  18 prepare() {
  19   cd "$pkgname-$pkgver"
  20   cargo fetch --locked --target "$CARCH-unknown-linux-gnu"
  21   patch -Np1 -i "../$pkgname-$pkgver-fix-tests.patch"
  22 }
  23
  24 build() {
  25   cd "$pkgname-$pkgver"
  26   cargo build --release --frozen
  27 }
  28
  29 check() {
  30   cd "$pkgname-$pkgver"
  31   cargo test --frozen
  32 }
  33
  34 package() {
  35   cd "$pkgname-$pkgver"
  36   install -Dm 755 "target/release/$pkgname" -t "$pkgdir/usr/bin"
  37   install -Dm 644 README.md -t "$pkgdir/usr/share/doc/$pkgname"
  38   install -Dm 644 LICENSE-MIT -t "$pkgdir/usr/share/licenses/$pkgname"
  39 }
  40
  41 # vim: ts=2 sw=2 et: