lxinput/trunk/PKGBUILD

   1 # Maintainer: Balló György <ballogyor+arch at gmail dot com>
   2 # Contributor: Bartłomiej Piotrowski <bpiotrowski@archlinux.org>
   3 # Contributor: Filipp "Scorp" Andjelo <scorp@mailueberfall.de>
   4
   5 pkgbase=lxinput
   6 pkgname=(lxinput lxinput-gtk3)
   7 pkgver=0.3.5
   8 pkgrel=3
   9 pkgdesc="Small program to configure keyboard and mouse for LXDE"
  10 arch=('x86_64')
  11 url="https://lxde.org/"
  12 license=('GPL')
  13 groups=('lxde')
  14 depends=('gtk2' 'gtk3')
  15 makedepends=('intltool')
  16 source=(https://downloads.sourceforge.net/lxde/$pkgbase-$pkgver.tar.xz)
  17 sha256sums=('4e8f778a65a4afe2365b47e7899358aa4fab535343aa62c72a3cdc4cac1f6e88')
  18
  19 build() {
  20   # GTK+ 2 version
  21   [ -d gtk2 ] || cp -r $pkgbase-$pkgver gtk2
  22   cd gtk2
  23   ./configure --prefix=/usr
  24   make
  25
  26   cd "$srcdir"
  27   # GTK+ 3 version
  28   [ -d gtk3 ] || cp -r $pkgbase-$pkgver gtk3
  29   cd gtk3
  30   ./configure --prefix=/usr --enable-gtk3
  31   make
  32 }
  33
  34 package_lxinput() {
  35   groups=('lxde')
  36   depends=('gtk2')
  37
  38   cd gtk2
  39   make DESTDIR="$pkgdir" install
  40 }
  41
  42 package_lxinput-gtk3() {
  43   groups=('lxde-gtk3')
  44   pkgdesc+=' (GTK+ 3 version)'
  45   depends=('gtk3')
  46   conflicts=('lxinput')
  47
  48   cd gtk3
  49   make DESTDIR="$pkgdir" install
  50 }