lxpanel-gtk3/trunk/PKGBUILD

   1 # Maintainer: Balló György <ballogyor+arch at gmail dot com>
   2 # Contributor: Bartłomiej Piotrowski <bpiotrowski@archlinux.org>
   3 # Contributor: Angel Velasquez <angvp@archlinux.org>
   4 # Contributor: Juergen Hoetzel <juergen@archlinux.org>
   5
   6 pkgname=lxpanel-gtk3
   7 _pkgname=lxpanel
   8 pkgver=0.10.1
   9 pkgrel=1
  10 pkgdesc='Lightweight X11 desktop panel for LXDE (GTK+ 3 version)'
  11 arch=('x86_64')
  12 license=('GPL2')
  13 url='https://lxde.org/'
  14 groups=('lxde-gtk3')
  15 depends=('alsa-lib' 'curl' 'menu-cache' 'lxmenu-data' 'libfm-gtk3' 'libkeybinder3')
  16 makedepends=('intltool' 'docbook-xml' 'docbook-xsl' 'wireless_tools')
  17 optdepends=('wireless_tools: netstat plugin')
  18 conflicts=($_pkgname)
  19 source=(https://downloads.sourceforge.net/lxde/$_pkgname-$pkgver.tar.xz)
  20 sha256sums=('1e318f57d7e36b61c23a504d03d2430c78dad142c1804451061f1b3ea5441ee8')
  21
  22 prepare() {
  23   cd $_pkgname-$pkgver
  24
  25   # Disable pager plugin as it breaks panel layout with GTK+ 3
  26   # https://sourceforge.net/p/lxde/bugs/773/
  27   sed -i '/pager.c/d' plugins/Makefile.am
  28   sed -i '/STATIC_PAGER/d' src/private.h
  29   sed -i 's/libwnck-3.0//' configure.ac
  30   autoreconf -fi
  31 }
  32
  33 build() {
  34   cd $_pkgname-$pkgver
  35   ./configure \
  36     --sysconfdir=/etc \
  37     --prefix=/usr \
  38     --enable-gtk3
  39
  40   #https://bugzilla.gnome.org/show_bug.cgi?id=656231
  41   sed -i -e 's/ -shared / -Wl,-O1,--as-needed\0/g' libtool
  42
  43   make
  44 }
  45
  46 package() {
  47   cd $_pkgname-$pkgver
  48   make DESTDIR="$pkgdir" install
  49 }