magnum/trunk/PKGBUILD

   1 # Maintainer: Alexander F. Rødseth <xyproto@archlinux.org>
   2 # Contributor: Mosra <mosra@centrum.cz>
   3
   4 pkgname=magnum
   5 pkgver=2020.06
   6 pkgrel=3
   7 pkgdesc='C++11/C++14 graphics middleware for games and data visualization'
   8 arch=(x86_64)
   9 url='https://magnum.graphics'
  10 license=(MIT)
  11 depends=('corrade>=2020.06' glfw openal sdl2 vulkan-icd-loader)
  12 makedepends=(cmake git)
  13 optdepends=('magnum-plugins: import and export features')
  14 source=("git+https://github.com/mosra/magnum#commit=fac6f4da261930c7035bf51f66091e350905720b") # tag: v2020.06
  15 sha256sums=('SKIP')
  16
  17 prepare() {
  18 # Fix build with recent cmake
  19   sed -e '/CONFIG/d' -i $pkgname/modules/FindOpenAL.cmake
  20 }
  21
  22 build() {
  23   mkdir -p build
  24   cd build
  25   cmake ../$pkgname \
  26     -DCMAKE_CXX_FLAGS="$CXXFLAGS -ffat-lto-objects -Wfatal-errors" \
  27     -DCMAKE_INSTALL_PREFIX=/usr \
  28     -DWITH_AL_INFO=ON \
  29     -DWITH_ANYAUDIOIMPORTER=ON \
  30     -DWITH_ANYIMAGECONVERTER=ON \
  31     -DWITH_ANYIMAGEIMPORTER=ON \
  32     -DWITH_ANYSCENEIMPORTER=ON \
  33     -DWITH_AUDIO=ON \
  34     -DWITH_DISTANCEFIELDCONVERTER=ON \
  35     -DWITH_GLXAPPLICATION=ON \
  36     -DWITH_GLXCONTEXT=ON \
  37     -DWITH_IMAGECONVERTER=ON \
  38     -DWITH_MAGNUMFONT=ON \
  39     -DWITH_MAGNUMFONTCONVERTER=ON \
  40     -DWITH_OBJIMPORTER=ON \
  41     -DWITH_FONTCONVERTER=ON \
  42     -DWITH_GL_INFO=ON \
  43     -DWITH_GLFWAPPLICATION=ON \
  44     -DWITH_SDL2APPLICATION=ON \
  45     -DWITH_TGAIMAGECONVERTER=ON \
  46     -DWITH_TGAIMPORTER=ON \
  47     -DWITH_VK=ON \
  48     -DWITH_WAVAUDIOIMPORTER=ON \
  49     -DWITH_WINDOWLESSGLXAPPLICATION=ON
  50   make
  51 }
  52
  53 package() {
  54   make DESTDIR="$pkgdir" -C build install
  55   install -Dm644 $pkgname/COPYING -t "$pkgdir/usr/share/licenses/$pkgname/"
  56 }