mako/trunk/PKGBUILD

   1 # Maintainer: Brett Cornwall <ainola@archlinux.org>
   2 # Maintainer: Maxim Baz <$pkgname at maximbaz dot com>
   3 # Contributor: Drew DeVault
   4
   5 pkgname=mako
   6 pkgver=1.7.1
   7 pkgrel=3
   8 license=('MIT')
   9 pkgdesc='Lightweight notification daemon for Wayland'
  10 makedepends=("meson" "scdoc" "systemd" "wayland-protocols")
  11 depends=(
  12         "gdk-pixbuf2"
  13         "pango"
  14         "systemd-libs"
  15         "wayland"
  16 )
  17 optdepends=("jq: support for 'makoctl menu'")
  18 arch=("x86_64")
  19 url='https://mako-project.org'
  20 source=(
  21         "$pkgname-$pkgver.tar.gz::https://github.com/emersion/mako/releases/download/v$pkgver/mako-$pkgver.tar.gz"
  22         "$pkgname-$pkgver.tar.gz.sig::https://github.com/emersion/mako/releases/download/v$pkgver/mako-$pkgver.tar.gz.sig"
  23         "systemd-dbus-activation.patch"
  24 )
  25 validpgpkeys=("34FF9526CFEF0E97A340E2E40FDE7BE0E88F5E48") # emersion
  26 sha256sums=('4312ff6bc61708115b43b967a42813374de7a2022f10c84e20127606416c3c12'
  27             'SKIP'
  28             '4579a2673dcf2114779e10ed52d771f3930c2192e8e35d3e145163d9e0b45c20')
  29
  30 prepare() {
  31         patch -Np1 -i "$srcdir/systemd-dbus-activation.patch" -d "$pkgname-$pkgver"
  32 }
  33
  34 build() {
  35         arch-meson \
  36                 -Dbash-completions=true \
  37                 -Dfish-completions=true \
  38                 -Dzsh-completions=true \
  39                 -Dsd-bus-provider=libsystemd \
  40                 "$pkgname-$pkgver" build
  41         ninja -C build
  42 }
  43
  44 package() {
  45         DESTDIR="$pkgdir" ninja -C build install
  46         install -Dm644 -t "$pkgdir/usr/share/licenses/$pkgname/" "$pkgname-$pkgver/LICENSE"
  47         install -Dm644 -t "$pkgdir/usr/lib/systemd/user/" "$pkgname-$pkgver/contrib/systemd/mako.service"
  48 }