mantisbt/trunk/PKGBUILD

   1 # Maintainer: Maxime Gauduin <alucryd@archlinux.org>
   2 # Contributor: Alexander 'gridcol' Griesbaum <agrsbm@gmail.com>
   3 # Contributor: Ravenman <correo.cuervo@gmail.com>
   4 # Contributor: Anton Bazhenov <anton.bazhenov@gmail>
   5 # Contributor: Angel 'angvp' Velasquez <angvp@archlinux.com.ve>
   6
   7 pkgname=mantisbt
   8 pkgver=1.3.0
   9 pkgrel=2
  10 pkgdesc='Web-based issue tracking system'
  11 arch=('any')
  12 url='http://www.mantisbt.org/'
  13 license=('GPL')
  14 depends=('php')
  15 optdepends=('apache: Web server to run MantisBT'
  16             'curl: Twitter integration'
  17             'gd: Graphs support'
  18             'lighttpd: Web server to run MantisBT'
  19             'mariadb: SQL database'
  20             'nginx: Web server to run MantisBT'
  21             'php-pgsql: PostgreSQL database')
  22 backup=('etc/webapps/mantisbt/config_inc.php')
  23 install='mantisbt.install'
  24 source=("https://downloads.sourceforge.net/mantisbt/mantisbt-${pkgver}.tar.gz")
  25 sha256sums=('a223107ba9cf1a6a555031f662e81a297133ee9d88896704c689cea15506e2cc')
  26
  27 package() {
  28   install -dm 755 "${pkgdir}"/{etc/webapps/mantisbt,usr/share/webapps}
  29   cp -dr --no-preserve='ownership' mantisbt-${pkgver} "${pkgdir}"/usr/share/webapps/mantisbt
  30
  31   ln -s /etc/webapps/mantisbt/config_inc.php "${pkgdir}"/usr/share/webapps/mantisbt/config_inc.php
  32   cp "${pkgdir}"/usr/share/webapps/mantisbt/config/config_inc.php.sample "${pkgdir}"/etc/webapps/mantisbt/config_inc.php
  33
  34   find "${pkgdir}" -type d -exec chmod 755 {} +
  35   find "${pkgdir}" -type f -exec chmod 644 {} +
  36   chown http:http -R "${pkgdir}"/usr/share/webapps/mantisbt
  37 }
  38
  39 # vim: ts=2 sw=2 et: