onionshare/trunk/PKGBUILD

   1 # Maintainer: kpcyrd <kpcyrd[at]archlinux[dot]org>
   2 # Contributor: Kevin Azzam <aur at kevin.azz.am>
   3 # Contributor: Ye Shu <shuye02 at outlook.com>
   4
   5 pkgname=onionshare
   6 pkgver=2.6
   7 pkgrel=2
   8 pkgdesc='Share a file over Tor Hidden Services anonymously and securely'
   9 url='https://github.com/onionshare/onionshare'
  10 arch=('any')
  11 license=('GPL3')
  12 depends=('python' 'hicolor-icon-theme' 'tor' 'stem' 'python-requests' 'python-pysocks' 'python-flask' 'python-flask-httpauth' 'python-flask-socketio' 'python-gevent-websocket' 'python-psutil' 'python-pycryptodome' 'python-pyqt5' 'python-qrcode' 'python-unidecode' 'python-colorama' 'pyside2')
  13 makedepends=('python-setuptools')
  14 optdepends=(
  15   'python-nautilus: enable Nautilus right-click extension'
  16 )
  17 checkdepends=('python-pytest')
  18 source=(https://github.com/onionshare/${pkgname}/releases/download/v${pkgver}/${pkgname}-${pkgver}.tar.gz
  19         https://github.com/onionshare/${pkgname}/releases/download/v${pkgver}/${pkgname}-${pkgver}.tar.gz.asc
  20 )
  21 sha512sums=('8764688c902aab1681eb3c00e6bbf779fa1f419d96852ecd091da3d5bd60d86759835da21d06510c2d7f4456e1f7fb0014d5df0b9533f736ae2ff596a53ec75e'
  22             'SKIP')
  23 b2sums=('43ab80d23b1b169d94fd9511298f282f9b61f61026bdb46c14b4f02315564898e8de919ba3c1737e96343fe0ddc2bf6737fbcdf9ce3f4c5cff16b58381a86314'
  24         'SKIP')
  25
  26 validpgpkeys=('927F419D7EC82C2F149C1BD1403C2657CD994F73')
  27
  28 build() {
  29   cd ${pkgname}/cli
  30   python setup.py build
  31   cd ../desktop
  32   python setup.py build
  33 }
  34
  35 check() {
  36   cd ${pkgname}
  37   pushd cli
  38   PYTHONPATH=".:${PYTHONPATH}" pytest tests/
  39   popd
  40   pushd desktop
  41   #PYTHONPATH="src:../cli:${PYTHONPATH}" pytest tests/
  42 }
  43
  44 package() {
  45   cd ${pkgname}/cli
  46   python setup.py install --skip-build -O1 --root="${pkgdir}"
  47   cd ../desktop
  48   python setup.py install --skip-build -O1 --root="${pkgdir}"
  49
  50   install -Dm 644 org.onionshare.OnionShare.desktop -t "${pkgdir}/usr/share/applications/"
  51   install -Dm 644 org.onionshare.OnionShare.svg -t "${pkgdir}/usr/share/icons/hicolor/scalable/apps/"
  52   install -Dm 644 org.onionshare.OnionShare.appdata.xml -t "${pkgdir}/usr/share/metainfo/"
  53 }
  54
  55 # vim: ts=2 sw=2 et: